Qt高級——QMake快速入門

Qt高級——QMake快速入門

一、QMake簡介

qmake是Trolltech公司創建的用來為不同的平臺和編譯器書寫Makefile的工具。
qmake是一個用來簡化在不同平臺間開發工程的構建過程的工具。qmake會自動生成MakeFile文件，可以用于任何軟件項目中，無論是否由Qt編寫。
qmake會注意所有的編譯器和平臺的依賴性，開發者只需關注自己的代碼。qmake作為Qt庫和Qt所提供的工具的主要連編工具，可以自動的包含moc和uic的連編規則。

二、QMake入門教程

1、創建一個工程

創建一個應用，包含 hello.cpp、hello.h、main.cpp三個文件。
使用文本編輯器創建一個hello.pro文件，增加源文件、頭文件到工程文件hello.pro。

HEADERS += hello.h
SOURCES += hello.cpp
SOURCES += main.cpp

同時，也可以使用換行符一次增加多個文件。

SOURCES = hello.cpp \
          main.cpp

目標名稱會自動設置，一般與工程文件相同，當會用后綴區別不同的平臺。如，工程文件是hello.pro，Windows平臺的目標名稱是hello.exe，Unix平臺的目標名稱是hello。如果要使用不同的目標名稱，需要在工程文件hello.pro中設置。如：
TARGET = helloworld
最后就是配置CONFIG變量，對于Qt應用程序來說，給CONFIG賦值qt，QMake會鏈接相關的庫，并確保moc和uic相關的連編規則生成到MakeFile文件中。最終的hello.pro工程文件如下：

CONFIG += qt
HEADERS += hello.h
SOURCES += hello.cpp
SOURCES += main.cpp

在工程所在目錄打開命令行終端，使用qmake生成為應用生成MakeFile。
qmake -o Makefile hello.pro
對于Visual Studio開發者，qmake會生成.dsp或.vcproj文件。
qmake -tp vc hello.pro

2、增加工程的調試版

應用程序的 release版本不包含調試符號或其它調試信息。在開發過程中，生成帶調試信息的應用程序調試版本是很有用的。通過增加debug到CONFIG變量可以生成應用程序的調試版本。

CONFIG += qt debug
HEADERS += hello.h
SOURCES += hello.cpp
SOURCES += main.cpp

3、增加特定平臺的源文件

應用程序中特定平臺部分的源碼需要保持平臺獨立代碼的分離。現在有hellowin.cpp和hellounix.cpp兩個新文件。不能直接增加這兩個文件到SOURCES變量，因為這會導致這兩個文件直接生成到MakeFile文件，需要在qmake所運行的平臺的代碼塊中獨立處理。
對于Windows平臺，在一個簡單的代碼塊中增加平臺獨立的文件。

win32 {
SOURCES += hellowin.cpp}

如果qmake運行在Windows平臺上，會增加hellowin.cpp文件到源文件列表。如果qmake運行在其它平臺上，會忽略。現在創建一個代碼塊增加和Unix平臺相關的文件。

unix {
    SOURCES += hellounix.cpp}

工程文件hello.pro文件如下：

CONFIG += qt debug
HEADERS += hello.h
SOURCES += hello.cpp
SOURCES += main.cpp
win32 {
    SOURCES += hellowin.cpp}
unix {
    SOURCES += hellounix.cpp}

4、如果文件不存在中止qmake過程

如果某個文件不存在，不生成MakeFile文件。可以使用exists()函數檢查一個文件是否存在。通過使用error()函數可以中止qmake執行過程。對main.cpp文件檢查如下：

!exists( main.cpp ) {
    error( "No main.cpp file found" )}

如果main.cpp文件存在，exists(main.cpp)為true。
如果main.cpp文件不存在，!exists(main.cpp)為true。

CONFIG += qt debug
HEADERS += hello.h
SOURCES += hello.cpp
SOURCES += main.cpp
win32 {
    SOURCES += hellowin.cpp}
unix {
SOURCES += hellounix.cpp}
!exists( main.cpp ) {
    error( "No main.cpp file found" )}

5、檢查多個條件

假設在Windows平臺上，使用命令行運行應用程序，想通過qDebug()函數查看輸出狀態。除非在應用程序構建過程中使用console設置，否則看不到輸出狀態信息。通過將console增加到CONFIG變量可以在生成的MakeFile文件中生成相應的設置。
如果只在Windows平臺上debug版本時查看輸出信息。代碼如下：

win32 {
    debug {
        CONFIG += console
    }}

內嵌的作用域也可以使用冒號（:）連接在一起。

CONFIG += qt debug
HEADERS += hello.h
SOURCES += hello.cpp
SOURCES += main.cpp
win32 {
    SOURCES += hellowin.cpp}
unix {
SOURCES += hellounix.cpp}
!exists(main.cpp) {
    error("No main.cpp file found")}
win32:debug {
    CONFIG += console}

三、QMake創建工程

本文將講述如何設置基于Qt的三種通用工程類型的qmake工程文件。

1、QMake創建應用程序

app模板會告訴qmake生成一個構建應用程序的MakeFile。使用app模板，應用的類型可以增加一個選項到CONFIG變量定義中。
windows：應用是一個Windows GUI應用程序
console：應用是一個Windows控制臺應用。
使用app模板時，下列qmake系統變量會被識別，可以在應用程序的.pro文件中使用。
HEADERS：應用程序的頭文件列表
SOURCES：應用程序的源文件列表
FORMS：應用程序的UI（Qt Designer創建）文件列表
LEXSOURCES：應用程序的LEX原文件列表
YACCSOURCES：應用程序的YACC源文件列表
TARGET：應用程序的可執行文件名稱
DESTDIR：生成的目標文件的存放目錄
DEFINES：應用程序指定的預定義預處理器符號
INCLUDEPATH：編譯器的搜索頭文件路徑
DEPENDPATH：應用程序的依賴查找路徑
VPATH：尋找補充文件的搜索路徑
DEF_FILE： 應用程序鏈接的.def文件，僅支持Windows。
RC_FILE：應用程序的資源文件，僅支持Windows。
RES_FILE：應用程序鏈接的資源文件，僅支持Windows。
開發者可以直接使用有值的qmake系統變量，不必指定任何值。qmake會自動增加需要的默認值。
實例工程文件如下：

TEMPLATE = app
DESTDIR  = c:/helloapp
HEADERS += hello.h
SOURCES += hello.cpp
SOURCES += main.cpp
DEFINES += QT_DLL
CONFIG  += qt warn_on release

對于單個值的數據項，如模板或目的目錄，使用“=”，但多個值的數據項需要使用“+=”增加到已經存在相應類型的數據項中。如果使用“=”會使用新的值替換原來的值，例如，DEFINES=QT_DLL，所有其它的定義都會被刪除。

2、QMake創建庫

lib模板告訴qmake生成構建一個庫的MakeFile。使用lib模板時，除了app模板支持的系統變量，也支持VERSION變量。可以使用這些變量在.pro文件中指定庫的相關信息。當使用lib模板時，以下選項需要增加到CONFIG變量決定要構建的庫的類型。
dll：庫是一個共享庫
staticlib：庫是一個靜態庫
plugin：庫是一個插件，也支持dll選項
VERSION變量指定庫的版本信息
庫的目標文件名是平臺獨立的。例如，X11和Mac OS X，庫名稱使用lib 前綴，Windows平臺上，庫文件名不增加任何前綴。

3、QMake創建插件

插件使用lib模板構建，告訴qmake生成一個工程的MakeFile。
VERSION變量用于指定插件的版本信息。
就像普通庫一樣，VERSION變量用于指定插件的版本信息。Qt Designer插件會使用一套依賴于Qt配置的特定配置集進行構建。為了方便起見，這些設置可以通過增加designer到工程CONFIG變量開啟。例如：
CONFIG += designer plugin

4、QMake創建Debug 和Release

某些時候，構建同時支持debug和release的工程是必要的。雖然CONFIG變量有debug和release選項，但是debug選項會覆蓋release選項。
為了開啟工程同時支持debug和release，必須在CONFIG變量增加debug_and_release選項。

CONFIG += debug_and_release

CONFIG(debug, debug|release) {
    TARGET = debug_binary} else {
    TARGET = release_binary}

以上代碼塊會修改每一種模式的構建目標，確保目標有不同的文件名稱。為目標提供不同的名稱可以確保目標相互間不會被覆蓋。
當qmake處理工程文件時，會生成一個允許支持debug和release模式的MakeFile規則。可以通過以下方式調用：
make all
build_all選項增加到工程文件的CONFIG變量，可以確保工程默認會被兩種模式編譯。
CONFIG += build_all
這會允許Makefile使用默認規則處理。
make
build_all選項也可以確保目標的兩個版本在安裝規則被調用時被安裝。
make install
可以自定義依賴于目標平臺的構建目標的名稱。例如，一個庫或插件可以在Windows平臺使用不同于Unix平臺的命名規范。

CONFIG(debug, debug|release) {
    mac: TARGET = $$join(TARGET,,,_debug)
    win32: TARGET = $$join(TARGET,,d)}

在debug模式構建時，以上代碼塊的默認行為會修改構建目標使用的名稱。