C++?Cmake如何使用

本篇內容介紹了“C++ Cmake如何使用”的有關知識，在實際案例的操作過程中，不少人都會遇到這樣的困境，接下來就讓小編帶領大家學習一下如何處理這些情況吧！希望大家仔細閱讀，能夠學有所成！

引言

CMake是開源、跨平臺的構建工具，可以讓我們通過編寫簡單的配置文件去生成本地的Makefile，這個配置文件是獨立于運行平臺和編譯器的，這樣就不用親自去編寫Makefile了，而且配置文件可以直接拿到其它平臺上使用，無需修改，非常方便。

一 環境搭建

我使用的是ubuntu18.04，安裝cmake使用如下命令：

sudo apt install cmake

安裝完成后，在終端下輸入:

cmake -version

查看cmake版本

這樣cmake就安裝好了。

二 簡單入門

首先讓我們從最簡單的代碼入手，先來體驗下cmake是如何操作的。

2.1 項目結構

2.2 示例源碼

打開終端，輸入：

touch main.c CMakeLists.txt

編寫main.c，如下：

main.c

#include <stdio.h>

int main(void)
{
	printf("Hello World\n");
	return 0;
}

然后在main.c同級目錄下編寫CMakeLists.txt，內容如下：

CMakeLists.txt

cmake_minimum_required (VERSION 2.8)

project (demo)

add_executable(main main.c)

2.3 運行查看

在終端下切到main.c所在的目錄下，然后輸入以下命令運行cmake：

cmake .

輸出結果如下：

ps:此時，建議留意一下這個文件夾下多生成的文件都有哪些。

可以看到成功生成了Makefile，還有一些cmake運行時自動生成的文件。

然后在終端下輸入make：

可以看到執行cmake生成的Makefile可以顯示進度，并帶顏色。再看下目錄下的文件：

可以看到我們需要的可執行文件main也成功生成了！

然后運行main：

運行成功！

PS：如果想重新生成main，輸入make clean就可以刪除main這個文件。然后重新make就行。

需要注意的是：我希望你著重看一下這時候這個文件夾下都有哪些文件。

三 編譯多個源文件

3.1 在同一個目錄下有多個源文件

3.1.1 簡單版本

接下來進入稍微復雜的例子：在同一個目錄下有多個源文件。

3.1.1.1 項目結構

3.1.1.2 示例代碼

首先刪除之前的文件：

rm -rf CMakeFiles CMakeCache.txt cmake_install.cmake Makefile main

在之前的目錄下添加2個文件，testFunc.c和testFunc.h:

touch testFunc.c testFunc.h

添加完后整體文件結構如下：

testFunc.c

/*
** testFunc.c
*/

#include <stdio.h>
#include "testFunc.h"

void func(int data)
{
	printf("data is %d\n", data);
}

testFunc.h

/*
** testFunc.h
*/

#ifndef _TEST_FUNC_H_
#define _TEST_FUNC_H_

void func(int data);

#endif

修改main.c，調用testFunc.h里聲明的函數func()：

main.c

#include <stdio.h>

#include "testFunc.h"

int main(void)
{
	func(100);
	return 0;
}

修改CMakeLists.txt，在add_executable的參數里把testFunc.c加進來:

CMakeLists.txt

cmake_minimum_required (VERSION 2.8)

project (demo)

add_executable(main main.c testFunc.c)

3.1.1.3 運行查看

cmake .make

然后運行查看：

運行成功！

可以類推，如果在同一目錄下有多個源文件，那么只要在add_executable里把所有源文件都添加進去就可以了。

但是如果有一百個源文件，再這樣做就有點坑了，無法體現cmake的優越性。

因此cmake提供了一個命令可以把指定目錄下所有的源文件存儲在一個變量中，這個命令就是

aux_source_directory(dir var)

第一個參數dir是指定目錄，第二個參數var是用于存放源文件列表的變量。

接下來寫個進階版的demo使用一下這個變量。

3.1.2 進階版本

3.1.2.1 項目結構

3.1.2.2 示例源碼

刪除無關文件

rm -rf CMakeFiles CMakeCache.txt cmake_install.cmake main Makefile

創建文件：

touch testFunc1.c testFunc1.h

testFunc1.c

/*
** testFunc1.c
*/

#include <stdio.h>
#include "testFunc1.h"

void func1(int data)
{
	printf("data is %d\n", data);
}

testFunc1.h

/*
** testFunc1.h
*/

#ifndef _TEST_FUNC1_H_
#define _TEST_FUNC1_H_

void func1(int data);

#endif

再修改main.c，調用testFunc1.h里聲明的函數func1()：

main.c

#include <stdio.h>

#include "testFunc.h"
#include "testFunc1.h"

int main(void)
{
	func(100);
	func1(200);

	return 0;
}

修改CMakeLists.txt：

CMakeLists.txt

cmake_minimum_required (VERSION 2.8)

project (demo)

aux_source_directory(. SRC_LIST)

add_executable(main ${SRC_LIST})

使用aux_source_directory把當前目錄下的源文件存列表存放到變量SRC_LIST里;

然后在add_executable里調用SRC_LIST（注意調用變量時的寫法）。

3.1.2.3 運行查看

再次執行cmake和make，并運行main:

可以看到運行成功了。

aux_source_directory()也存在弊端，它會把指定目錄下的所有源文件都加進來，可能會加入一些我們不需要的文件，此時我們可以使用set命令去新建變量來存放需要的源文件，如下：

cmake_minimum_required (VERSION 2.8)

project (demo)

set( SRC_LIST
	 ./main.c
	 ./testFunc1.c
	 ./testFunc.c)

add_executable(main ${SRC_LIST})

3.2 在不同目錄下有多個源文件

一般來說，當程序文件比較多時，我們會進行分類管理，把代碼根據功能放在不同的目錄下，這樣方便查找。那么這種情況下如何編寫CMakeLists.txt呢？

3.2.1 項目結構

我們把之前的源文件整理一下（新建2個目錄test_func和test_func1）：

cmake_minimum_required (VERSION 2.8)

project (demo)

set( SRC_LIST
	 ./main.c
	 ./testFunc1.c
	 ./testFunc.c)

add_executable(main ${SRC_LIST})

整理好后整體文件結構如下：

把之前的testFunc.c和testFunc.h放到test_func目錄下，testFunc1.c和testFunc1.h則放到test_func1目錄下。

3.2.2 示例源碼

其中，CMakeLists.txt和main.c在同一目錄下，內容修改成如下所示：

cmake_minimum_required (VERSION 2.8)

project (demo)

include_directories (test_func test_func1)

aux_source_directory (test_func SRC_LIST)
aux_source_directory (test_func1 SRC_LIST1)

add_executable (main main.c ${SRC_LIST} ${SRC_LIST1})

這里出現了一個新的命令：include_directories。

該命令是用來向工程添加多個指定頭文件的搜索路徑，路徑之間用空格分隔。

因為main.c里include了testFunc.h和testFunc1.h，如果沒有這個命令來指定頭文件所在位置，就會無法編譯。當然，也可以在main.c里使用include來指定路徑，如下

#include "test_func/testFunc.h"
#include "test_func1/testFunc1.h"

只是這種寫法不好看。

另外，我們使用了2次aux_source_directory，因為源文件分布在2個目錄下，所以添加2次。

3.2.2 運行查看

四 項目級的組織結構

正規一點來說，一般會把源文件放到src目錄下，把頭文件放入到include文件下，生成的對象文件放入到build目錄下，最終輸出的可執行程序文件會放到bin目錄下，這樣整個結構更加清晰。

4.1 項目結構

讓我們把前面的文件再次重新組織下：

4.2 示例源碼

修改CMakeLists.txt：

CMakeLists.txt

cmake_minimum_required (VERSION 2.8)

project (demo)

add_subdirectory (src)

add_subdirectory：這個語句的作用是增加編譯子目錄。其基本語法格式是：

add_subdirectory(source_dir [binary_dir] [EXCLUDE_FROM_ALL])

一共有三個參數，后兩個是可選參數.

source_dir 源代碼目錄

指定一個包含CMakeLists.txt和代碼文件所在的目錄，該目錄可以是絕對路徑，也可以是相對路徑，對于后者相對路徑的起點是CMAKE_CURRENT_SOURCE_DIR。此外，如果子目錄再次包含的CMakeLists.txt，則將繼續處理里層的CMakeLists.txt，而不是繼續處理當前源代碼。

binary_dir 二進制代碼目錄

這個目錄是可選的，如果指定，cmake命令執行后的輸出文件將會存放在此處，若沒有指定，默認情況等于source_dir沒有進行相對路徑計算前的路徑，也就是CMAKE_BINARY_DIR。

EXCLUDE_FROM_ALL標記

這個標志是可選的，如果傳遞了該參數表示新增加的子目錄將會排除在ALL目錄之外（可能是make系統中的make all？），表示這個目錄將從IDE的工程中排除。用戶必須顯式在子文件這個編譯目標（手動cmake之類的）。指定了這個文件夾，表示這個文件夾是獨立于源工程的，這些函數是有用但是不是必要的，比如說我們一系列的例子。

add_subdirectory 這個命令用于添加源文件子目錄，同時還可以指定中間二進制和目標二進制的生成路徑。EXCLUDE_FROM_ALL將會將這個目錄從編譯中排除，如工程的例子需要等待其他編譯完成后再進行單獨的編譯。通常子目錄應該包含自己的project()命令，這樣以來整個編譯命令將會產生各自的目標文件。如果把CMakeLists.txt與VS IDE比較，總的CMakeLists.txt就相當于解決方案，子CMakeLists.txt就相當于在解決方案下的工程文件。還有一個需要注意的是，如果編譯父CMakeLists時依賴了子CMakeLists.txt中的源文件，那么該標志將會被覆蓋（也就是也會處理），以滿足編譯任務。

這里指定src目錄下存放了源文件，當執行cmake時，就會進入src目錄下去找src目錄下的CMakeLists.txt，所以在src目錄下也建立一個CMakeLists.txt，內容如下:

src/CMakeLists.txt

aux_source_directory (. SRC_LIST)

include_directories (../include)

add_executable (main ${SRC_LIST})

set (EXECUTABLE_OUTPUT_PATH ${PROJECT_SOURCE_DIR}/bin)

這里的set其實是和前面的一樣，只是EXECUTABLE_OUTPUT_PATH是個系統自帶的預定義變量，其意義如下：

• EXECUTABLE_OUTPUT_PATH ：目標二進制可執行文件的存放位置

• PROJECT_SOURCE_DIR：工程的根目錄

所以，這里set的意思是把存放elf文件的位置設置為工程根目錄下的bin目錄。（cmake有很多預定義變量，詳細的可以網上搜索一下）

添加好以上這2個CMakeLists.txt后，整體文件結構如下：

4.3 運行查看

下面來運行cmake，不過這次先讓我們切到build目錄下:

cd buildcmake ..make

這樣Makefile會在build目錄下生成，二進制程序會在bin目錄下生成，然后運行可執行程序：

cd ../bin
./main

這里解釋一下為什么在build目錄下運行cmake？
還記得在第一個例子里我讓你著重看一下cmake和make之后會生成什么文件嗎？這個過程中會生成很多文件，但是可惜的是跟我們的運行并沒有什么關系，因此，如果能把編譯隔離在某個文件夾，這樣cmake的時候所有的中間文件都將在這個目錄下生成，刪除的時候也很好刪除，非常方便。如果不這樣做，cmake運行時生成的附帶文件就會跟源碼文件混在一起，這樣會對程序的目錄結構造成污染。
另外一種寫法：
前面的工程使用了2個CMakeLists.txt，最外層的CMakeLists.txt用于掌控全局，使用add_subdirectory來控制其它目錄下的CMakeLists.txt的運行。

上面的例子也可以只使用一個CMakeLists.txt，把最外層的CMakeLists.txt內容改成如下

CMakeLists.txt

cmake_minimum_required (VERSION 2.8)

project (demo)

set (EXECUTABLE_OUTPUT_PATH ${PROJECT_SOURCE_DIR}/bin)

aux_source_directory (src SRC_LIST)

include_directories (include)

add_executable (main ${SRC_LIST})

同時，還要把src目錄下的CMakeLists.txt刪除。

然后正常編譯運行就可以。

五 動態庫和靜態庫的編譯控制

有時只需要編譯出動態庫和靜態庫，然后等著讓其它程序去使用。讓我們看下這種情況該如何使用cmake。

關于什么是靜態庫和動態庫以及如何使用它們，請參見我的另一篇博客【C++】靜態庫與動態庫的生成與使用介紹

5.1 生成庫文件

5.1.1 項目結構

首先按照如下重新組織文件，只留下testFunc.h和TestFunc.c

我們會在build目錄下運行cmake，并把生成的庫文件存放到lib目錄下。

5.1.2 示例源碼

CMakeLists.txt

cmake_minimum_required (VERSION 3.5)

project (demo)

set (SRC_LIST ${PROJECT_SOURCE_DIR}/testFunc/testFunc.c)

add_library (testFunc_shared SHARED ${SRC_LIST})
add_library (testFunc_static STATIC ${SRC_LIST})

set_target_properties (testFunc_shared PROPERTIES OUTPUT_NAME "testFunc")
set_target_properties (testFunc_static PROPERTIES OUTPUT_NAME "testFunc")

set (LIBRARY_OUTPUT_PATH ${PROJECT_SOURCE_DIR}/lib)

這里又出現了新的命令和預定義變量:

• add_library: 生成動態庫或靜態庫(第1個參數指定庫的名字；第2個參數決定是動態還是靜態，如果沒有就默認靜態；第3個參數指定生成庫的源文件)

• set_target_properties: 設置最終生成的庫的名稱，還有其它功能，如設置庫的版本號等

• LIBRARY_OUTPUT_PATH: 庫文件的默認輸出路徑，這里設置為工程目錄下的lib目錄

PS：前面使用set_target_properties重新定義了庫的輸出名稱，如果不使用set_target_properties也可以，那么庫的名稱就是add_library里定義的名稱，只是連續2次使用add_library指定庫名稱時（第一個參數），這個名稱不能相同，而set_target_properties可以把名稱設置為相同，只是最終生成的庫文件后綴不同（一個是.so，一個是.a），這樣相對來說會好看點。

5.1.3 運行查看

cd build/
cmake ..
make
cd ../lib/
ls

5.2 鏈接庫文件

既然我們已經生成了庫，那么就進行鏈接測試下。

5.2.1 項目結構

重新建一個工程目錄，然后把上節生成的庫拷貝過來，然后在在工程目錄下新建src目錄和bin目錄，在src目錄下添加一個main.c，整體結構如下：

5.2.2 示例源碼

main.c

#include <stdio.h>

#include "testFunc.h"

int main(void)
{
    func(100);
    
    return 0;
}

CMakeLists.txt

cmake_minimum_required (VERSION 3.5)

project (demo)


set (EXECUTABLE_OUTPUT_PATH ${PROJECT_SOURCE_DIR}/bin)

set (SRC_LIST ${PROJECT_SOURCE_DIR}/src/main.c)

# find testFunc.h
include_directories (${PROJECT_SOURCE_DIR}/testFunc/inc)

find_library(TESTFUNC_LIB testFunc HINTS ${PROJECT_SOURCE_DIR}/testFunc/lib)

add_executable (main ${SRC_LIST})

target_link_libraries (main ${TESTFUNC_LIB})

這里出現2個新的命令，

• find_library: 在指定目錄下查找指定庫，并把庫的絕對路徑存放到變量里，其第一個參數是變量名稱，第二個參數是庫名稱，第三個參數是HINTS，第4個參數是路徑，其它用法可以參考cmake文檔

• target_link_libraries: 把目標文件與庫文件進行鏈接

使用find_library的好處是在執行cmake …時就會去查找庫是否存在，這樣可以提前發現錯誤，不用等到鏈接時。

5.2.3 運行查看

cd到build目錄下，然后運行cmake … && make，最后進入到bin目錄下查看，發現main已經生成，運行之：

cd build/
cmake ..
make
cd ../bin/
./main

ps：在lib目錄下有testFunc的靜態庫和動態庫，find_library(TESTFUNC_LIB testFunc
…默認是查找動態庫，如果想直接指定使用動態庫還是靜態庫，可以寫成find_library(TESTFUNC_LIB
libtestFunc.so …或者find_library(TESTFUNC_LIB libtestFunc.a …

ps： 查看elf文件使用了哪些庫，可以使用readelf -d ./xx來查看 例：readelf -d ./main

六 條件編譯

有時編譯程序時想添加一些編譯選項，如-Wall，-std=c++11等，就可以使用add_compile_options來進行操作。
這里以一個簡單程序來做演示。

6.1 簡單程序

6.1.1 項目結構

6.1.2 示例代碼

main.cpp

#include <iostream>

int main(void)
{
    auto data = 100;
    std::cout << "data: " << data << "\n";
    return 0;
}

CMakeLists.txt

cmake_minimum_required (VERSION 2.8)

project (demo)

set (EXECUTABLE_OUTPUT_PATH ${PROJECT_SOURCE_DIR}/bin)

add_compile_options(-std=c++11 -Wall) 

add_executable(main main.cpp)

6.1.3 運行查看

然后cd到build目錄下，執行cmake … && make命令，就可以在bin目錄下得到main的可執行文件

6.2 添加編譯選項

有時希望在編譯代碼時只編譯一些指定的源碼，可以使用cmake的option命令，主要遇到的情況分為2種：

• 本來要生成多個bin或庫文件，現在只想生成部分指定的bin或庫文件

• 對于同一個bin文件，只想編譯其中部分代碼（使用宏來控制）

6.2.1 生成部分指定bin或庫文件

6.2.1.1 項目結構

假設我們現在的工程會生成2個bin文件，main1和main2，項目結構如下：

6.2.1.2 示例源碼

CMakeLists.txt

cmake_minimum_required(VERSION 3.5)

project(demo)

option(MYDEBUG "enable debug compilation" OFF)

set (EXECUTABLE_OUTPUT_PATH ${PROJECT_SOURCE_DIR}/bin)

add_subdirectory(src)

這里使用了option命令，其第一個參數是這個option的名字，第二個參數是字符串，用來描述這個option是來干嘛的，第三個是option的值，ON或OFF，也可以不寫，不寫就是默認OFF。

然后編寫src目錄下的CMakeLists.txt，如下：

src/CMakeLists.txt

cmake_minimum_required (VERSION 3.5)

add_executable(main1 main1.c)

if (MYDEBUG)
    add_executable(main2 main2.c)
else()
    message(STATUS "Currently is not in debug mode")    
endif()

注意，這里使用了if-else來根據option來決定是否編譯main2.c,其中main1.c和main2.c的內容如下:

main1.c

// main1.c
#include <stdio.h>

int main(void)
{
    printf("hello, this main1\n");
    
    return 0;
}

main1.c

// main2.c
#include <stdio.h>

int main(void)
{
    printf("hello, this main2\n");
    
    return 0;
}

6.2.1.3 運行查看

然后cd到build目錄下輸入cmake … && make就可以只編譯出main1，如果想編譯出main2，就把MYDEBUG設置為ON，再次輸入cmake … && make重新編譯。

每次想改變MYDEBUG時都需要去修改CMakeLists.txt，有點麻煩，其實可以通過cmake的命令行去操作，例如我們想把MYDEBUG設置為OFF，先cd到build目錄，然后輸入cmake … -DMYDEBUG=ON，這樣就可以編譯出main1和main2 （在bin目錄下）

6.2.2 編譯部分代碼

假設我們有個main.c，其內容如下：

main.c

#include <stdio.h>

int main(void)
{
#ifdef WWW1
    printf("hello world1\n");
#endif    

#ifdef WWW2     
    printf("hello world2\n");
#endif

    return 0;
}

可以通過定義宏來控制打印的信息，我們CMakeLists.txt內容如下:

cmake_minimum_required(VERSION 3.5)

project(demo)

set (EXECUTABLE_OUTPUT_PATH ${PROJECT_SOURCE_DIR}/bin)

option(WWW1 "print one message" OFF)
option(WWW2 "print another message" OFF)

if (WWW1)
    add_definitions(-DWWW1)
endif()

if (WWW2)
    add_definitions(-DWWW2)
endif()

add_executable(main main.c)

這里把option的名字保持和main.c里的宏名稱一致，這樣更加直觀，也可以選擇不同的名字。通過與add_definitions()的配合，就可以控制單個bin文件的打印輸出了。

整體工程結構如下：

cd到build目錄下執行cmake … && make，然后到bin目錄下執行./main，可以看到打印為空，
接著分別按照下面指令去執行，然后查看打印效果，

• cmake … -DWWW1=ON -DWWW2=OFF && make

• cmake … -DWWW1=OFF -DWWW2=ON && make

• cmake … -DWWW1=ON -DWWW2=ON && make

這里有個小坑要注意下：假設有2個options叫A和B，先調用cmake設置了A，下次再調用cmake去設置B，如果沒有刪除上次執行cmake時產生的緩存文件，那么這次雖然沒設置A，也會默認使用A上次的option值。

所以如果option有變化，要么刪除上次執行cmake時產生的緩存文件，要么把所有的option都顯式的指定其值。

“C++ Cmake如何使用”的內容就介紹到這里了，感謝大家的閱讀。如果想了解更多行業相關的知識可以關注億速云網站，小編將為大家輸出更多高質量的實用文章！