批處理如何實現自動檢測所有盤然后刪除所有分區的默認共享

這篇文章主要介紹了批處理如何實現自動檢測所有盤然后刪除所有分區的默認共享，具有一定借鑒價值，感興趣的朋友可以參考下，希望大家閱讀完這篇文章之后大有收獲，下面讓小編帶著大家一起了解一下。

刪除所有分區的默認共享.bat

代碼如下:

@echo off
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
::
::     先列舉存在的分區，然后再逐個刪除以分區名命名的共享；
::     通過修改注冊表防止admin$共享在下次開機時重新加載； 
::     IPC$共享需要administritor權限才能成功刪除
::
::                             jm 改動于 2006-5-12
::
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

title 默認共享刪除器
echo. 
echo ------------------------------------------------------ 
echo. 
echo 開始刪除每個分區下的默認共享. 
echo. 
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do @(
    if exist %%a:\nul (
        net share %%a$ /delete>nul 2>nul && echo 成功刪除名為 %%a$ 的默認共享 || echo 名為 %%a$ 的默認共享不存在
    ) 
)
net share admin$ /delete>nul 2>nul && echo 成功刪除名為 admin$ 的默認共享 || echo 名為 admin$ 的默認共享不存在
echo.
echo ------------------------------------------------------ 
echo.
net stop Server>nul 2>nul && echo Server服務已停止.
net start Server>nul 2>nul && echo Server服務已啟動.
echo. 
echo ------------------------------------------------------ 
echo. 
echo 修改注冊表以更改系統默認設置. 
echo. 
echo 正在創建注冊表文件. 
echo Windows Registry Editor Version 5.00> c:\delshare.reg 
:: 通過注冊表禁止Admin$共享，以防重啟后再次加載
echo [HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\lanmanserver\parameters]>> c:\delshare.reg
echo "AutoShareWks"=dword:00000000>> c:\delshare.reg 
echo "AutoShareServer"=dword:00000000>> c:\delshare.reg 
:: 刪除IPC$共享，本功能需要administritor權限才能成功刪除
echo [HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa]>> c:\delshare.reg
echo "restrictanonymous"=dword:00000001>> c:\delshare.reg
echo 正在導入注冊表文件以更改系統默認設置. 
regedit /s c:\delshare.reg 
del c:\delshare.reg && echo 臨時文件已經刪除. 
echo. 
echo ------------------------------------------------------ 
echo. 
echo 程序已經成功刪除所有的默認共享. 
echo. 
echo 按任意鍵退出...
pause>nul

感謝你能夠認真閱讀完這篇文章，希望小編分享的“批處理如何實現自動檢測所有盤然后刪除所有分區的默認共享”這篇文章對大家有幫助，同時也希望大家多多支持億速云，關注億速云行業資訊頻道，更多相關知識等著你來學習!