批處理中Set命令怎么用

小編給大家分享一下批處理中Set命令怎么用，相信大部分人都還不怎么了解，因此分享這篇文章給大家參考一下，希望大家閱讀完這篇文章后大有收獲，下面讓我們一起去了解一下吧！

set,E文翻譯過來就是“設置”的意思，相當于數學里的“令”。
如：set X=5，就是令X=5的意思。
語法形式：
SET [variable=[string]]
SET /P variable=[promptString] 
SET /A expression    

一、SET [variable=[string]] 

示例1:
@echo off 
set
pause 
顯示所有的變量的值

示例2: 

@echo off 
set var=我是值 
echo %var% 
pause 
請看 set var=我是值 ,這就是BAT直接在批處理中設置變量的方法! 
set 是命令 var是變量名 =號右邊的"我是值"是變量的值 
在批處理中我們要引用這個變量就把var變量名用兩個%(百分號)擴起來,如%var%   

二、SET /P variable=[promptString] 

有時候我們需要提供一個交互界面,讓  用戶自己輸入變量的值,然后我們在來根據這個值來做相應操作,現在我就來說說這SET的這  種語法,只需要加一個"/P"參數就可以了! 
實例1: 
@echo off 
set /p var=請輸入你的名字:  
echo 您的名字是:%var%
pause   
set /p 是命令語法 var是變量名 =號右邊的"請輸入變量的值: ",這個是提示語,不是變 
量的值了! 
運行后,我們在提示語后面直接輸入robin,就會顯示一行您” 您的名字是:robin”  

三、SET /A expression  

/A 命令行開關指定等號右邊的字符串為被評估的數字表達式。
該表達式解析很簡單并以遞減的優先權順序支持下列操作:
() - 分組 
! ~ - - 一元運算符 
* / % - 算數運算符 
+ - - 算數運算符 
<< >> - 邏輯移位 
& - 按位“與” 
^ - 按位“異” 
| - 按位“或” 
= *= /= %= += -= &= ^= |= <<= >>= - 賦值
, - 表達式分隔符 
set的/A參數就是讓SET可以支持數學符號進行加減等一些數學運算! 
現在開始舉例子介紹這些數學符號的用法: 
看例子 這里的例子請直接在CMD下拷貝命令運行,不需要保存為BAT! 
set /a var=1 + 1  
set /a 語法, var變量名 1 + 1 數學式子 
  拷貝運行后會直接顯示一個2,或者運行完后我們輸入echo %var%,也是二,這就是 
一個簡單的加法運算! 

代碼如下:

set /a var=2 - 1 結果是多少呢?如果你看不到結果就echo %var%..... 
set /a var=2 * 2 乘法運算 
set /a var=2 / 2 除法運算 
set /a var=(1+1) + (1+1) 結果等于4 看得懂吧! 

實例1：

代碼如下:

@echo off
set /a a=1+1,b=2+1,c=3+1
echo %a% %b% %c%

實例2：

代碼如下:

@echo off
set a=100
set b=1000
set /a c=a+b
echo the result is :%c%
pause

有時候我們需要直接在原變量進行加減操作就可以用這種語法 
set /a var+=1 這樣的語法對應原始語法就是set /a var = %var% + 1 
都是一樣的結果,在原變量的值上在進行數學運算,不過這樣寫簡單一點 
在來一個:  
set /a var*=2  
其他都這么用,只要幫助里有這個語法! 
另外還有一些用邏輯或取余操作符,這些符號,按照上面的使用方法會報錯的 
比如我們在CMD里輸入set /a var=1 & 1 "與運算",他并不會顯示為1,而是報錯, 
為什么?對于這樣的"邏輯或取余操作符",我們需要把他們用雙引號引起來,看例子 

代碼如下:

set /a var= 1 "&" 1 這樣結果就顯示出來了,其他邏輯或取余操作符用法 
set /a var= 1 "^" 1 異運算 
set /a var= 1 "%" 1 取模運算 
set /a var= 2 "<<" 2 位左移 
set /a var= 4 ">>" 2 位右移

實例3：

代碼如下:

@echo off
set a=100
set b=1000
set /a c=a+b
set /a c= c "<<" 2
echo the result is :%c%
pause

這些符號也可以用&= ^= |= <<= >>= 這樣的簡單用法如 
set /a var"&=" 1 等于set /a var = %var% "&" 1 注意引號 
set的通常用法示例：
1、set 顯示環境變量：
如：在命令行下輸入：
set 會顯示當前所有的系統環境變量
set c 會顯示所有的以c開頭或C開頭的變量（也即不區分大小寫）；
set com 會顯示所有的以com開頭或COM開頭的變量（不區分大小寫）；
2、set 設置環境變量，用法示例：set 表達式，
如：set str=ok
就是將變量str的值設置成字符串“OK”
注意：set str=ok>
這個在批處理運行過程中會出錯，系統會提示：“命令語法不正確。”
原因是，因為 變量str 中的值“ok>”的字符">"為一特殊字符，會被系統當成 定向 符處理，所以會運行出錯，那如果確實要設置這樣的變量str，值為 "ok>"怎么辦呢？解決辦法有二：將特殊字符轉義，轉義方法在該特殊字符前加一個“^”，如：set str=ok^> (這種方法比較少用，因為沒有多少應用價值)
常見的解決辦法，在set后面將整個表達式用 引號括起來，如：set "str=>"
3、帶參數 /a的set 數值計算
set的/A參數就是讓SET可以支持數學符號進行加減等一些數學運算! 支持的數學運算包含（優先權遞減）:
() - 分組
! ~ - - 一元運算符
* / % - 算數運算符
+ - - 算數運算符
&lt;&lt; &gt;&gt; - 邏輯移位
& - 按位“與”
^ - 按位“異”
| - 按位“或”
= *= /= %= += -= - 賦值
&= ^= |= &lt;&lt;= &gt;&gt;=
, - 表達式分隔符
用法示例：set /a num=2*10,這樣變量num的值將變為：20

代碼如下:

set /a var=2 - 1 結果是多少呢?如果你看不到結果就echo %var%.....
set /a var=2 * 2 乘法運算
set /a var=2 / 2 除法運算
set /a var=(1+1) + (1+1) 結果等于4 看得懂吧!
set /a a=1+1,b=2+1,c=3+1 運行后會顯示一個4,但我們用
echo %a% %b% %c%后看結果,會發現其他數學運算也有效果!,這就是"斗"號的
作用!

有時候我們需要直接在原變量進行加減操作就可以用這種語法
set /a var+=1 這樣的語法對應原始語法就是set /a var = %var% + 1
都是一樣的結果。
對于"邏輯或取余操作符",我們需要把他們用雙引號引起來,看例子

代碼如下:

set /a var= 1 "&" 1 這樣結果就顯示出來了,其他邏輯或取余操作符用法
set /a var= 1 "+" 1 異運算
set /a var= 1 "%" 1 取模運算
set /a var= 2 "&lt;&lt;" 2 次方運算
set /a var= 4 "&gt;&gt;" 2 這個不太記得數學里的叫法....

這些符號也可以用&= ^= |= &lt;&lt;= &gt;&gt;= 這樣的簡單用法如
set /a var"&=" 1 等于set /a var = %var% "&" 1 注意引號

4、帶參數 /p 的set 等待用戶輸入
windows 2000 和windows 是沒有choice這個命令，choice的等待用戶輸入功能就要通過set /p來實現
演示如下：

代碼如下:

@echo off
set /p str=請輸入你想輸入的字符：
echo 你輸入的字符串為：%str%
pause>nul

set /p的特殊應用（set /p=<nul相當于輸出字符并不帶回車，利用這個性質，可以做出比較漂亮的動畫），用法示例：

代碼如下:

@echo off
for /l %%i in (1 1 70) do (
set /p=O<nul
for /l %%a in (1 1 50) do ver>nul
)
pause>nul

注：代碼中用到了一句for /l %%a in (1 1 50) do ver>nul，它的目的是利用for循環運行某一命令來達到延時的目的。
5、利用set截取字符 保存下面的代碼為test.bat運行查看即可。

代碼如下:

@echo off&color 1f&rem num=15 nums=30
mode con: cols=80 lines=35
set "var=1234567890"
set "num= "
set "nums= "
rem 第一屏 舍棄
cls&echo 第一屏 舍棄
echo\&echo %num% var=%var%&echo\
for /l %%i in (1 1 3) do call :dan %%i
echo\
for /l %%i in (0 1 1) do call :yi %%i
echo\
for /l %%i in (0 1 2) do call :_yi %%i
echo ~ 波浪號后面的數字：為正數表示舍棄變量的前位;
echo , 逗號后面的數字為正數表示取變量的舍棄以后的前幾位;
echo , 逗號后面為負數表示舍棄變量的后幾位
echo\&echo\&pause&color 1e
rem 第二屏 取
cls&echo 第二屏 取
echo\&echo %num% var=%var%&echo\
for /l %%i in (-1 -1 -3) do call :dan %%i
echo\
for /l %%i in (-4 -1 -6) do call :er %%i
echo\
call :_er -8
echo ~ 波浪號后面直接跟負數表示取變量的后幾位
echo , 逗號后面的數字為正數表示取變量的舍棄以后的前幾位;
echo , 逗號后面為負數表示舍棄變量的后幾位
echo\&echo\&pause&color 1f
rem 第三屏 替換 刪除
cls&echo 第三屏 替換 刪除
set "var=abc:\123\ef:g\123\456"hij"789"klm\"
echo\&echo %num%var=%var%
echo\
call :san
echo = 號左邊為要替換掉的字符, 右邊為需替換來的字符
echo = 號左邊要替換掉的字符前面加個*號,代表第一次出現的字符及其前面的所有字符
echo\
echo ========= 演示完畢 ========= 按任意鍵退出 ==========
pause>nul
exit
:dan
set shu=%1
if %shu% lss 0 (set aa=取&set ji=最后) else set aa=舍棄&set ji=前
if "%shu:~0,1%"=="-" set shu=%shu:~1%
set str1=%%var:~%1%%%num%
set str2=%aa%var的%ji%%shu%位%nums%
call set str3=%%var:~%1%%%num%
call echo %%str1:~0,15%% %%str2:~0,30%% %%str3:~0,15%%
goto :eof
:yi
set shu=%1
if %shu% lss 0 (set aa=取&set ji=最后) else set aa=舍棄&set ji=前
for /l %%i in (1 1 3) do (
set str1=%%var:~%1,%%i%%%num%
set str2=%aa%var的%ji%%shu%位之后取%%i位%nums%
call set str3=%%var:~%1,%%i%%%num%
call echo %%str1:~0,15%% %%str2:~0,26%% %%str3:~0,15%%
if %%i==3 echo\
)
goto :eof
:_yi
for /l %%i in (-1 -1 -3) do (
set str1=%%var:~%1,%%i%%%num%
set str2=舍棄var的前%1位和%%i位%nums%
call set str3=%%var:~%1,%%i%%%num%
call echo %%str1:~0,15%% %%str2:~0,28%% %%str3:~0,15%%
if %%i==-3 echo\
)
goto :eof
:er
set sss=%1
set sss=%sss:~1%
for /l %%i in (1 1 3) do (
set str1=%%var:~%1,%%i%%%num%
set str2=從var的倒數%sss%位開始取%%i位%nums%
call set str3=%%var:~%1,%%i%%%num%
call echo %%str1:~0,15%% %%str2:~0,24%% %%str3:~0,15%%
if %%i==3 echo\
)
goto :eof
:_er
set sss=%1
set sss=%sss:~1%
for /l %%i in (-1 -1 -3) do (
set str1=%%var:~%1,%%i%%%num%
set str2=從var的倒數%sss%位開始并舍棄最后%%i位%nums%
call set str3=%%var:~%1,%%i%%%num%
call echo %%str1:~0,15%% %%str2:~0,20%% %%str3:~0,15%%
if %%i==-3 echo\
)
goto :eof
:san
set str1=%%var:"=%%%num%
set str2=刪除var中的所有^"號%num%
set str3=%var:"=%%nums%
call echo %%str1:~0,13%% %%str2:~0,23%% %%str3:~0,30%%
set str1=%%var:\=%%%num%
set str2=刪除var中的所有\號%num%
set str3=%var:\=%%nums%
call echo %%str1:~0,13%% %%str2:~0,23%% %%str3:~0,30%%
set str1=%%var::=%%%num%
set str2=刪除var中的所有:號%num%
set str3=%var::=%%nums%
call echo %%str1:~0,13%% %%str2:~0,23%% %%str3:~0,30%%
echo\
set str1=%%var:"=好%%%num%
set str2=替換var中的所有^"號為好字%num%
set str3=%var:"=好%%nums%
call echo %%str1:~0,12%% %%str2:~0,20%% %%str3:~0,30%%
set str1=%%var:\=好%%%num%
set str2=替換var中的所有\號為好字%num%
set str3=%var:\=好%%nums%
call echo %%str1:~0,12%% %%str2:~0,20%% %%str3:~0,30%%
set str1=%%var::=好%%%num%
set str2=替換var中的所有:號為好字%num%
set str3=%var::=好%%nums%
call echo %%str1:~0,12%% %%str2:~0,20%% %%str3:~0,30%%
echo\
set str1=%%var:*"=%%%num%
set str3=%var:*"=%%nums%
echo 刪除var中的第一次出現的^"號及其前面的所有字符
call echo %%str1:~0,15%% %%str3:~0,30%%
echo.
set str1=%%var:*\=%%%num%
set str3=%var:*\=%%nums%
echo 刪除var中的第一次出現的\號及其前面的所有字符
call echo %%str1:~0,15%% %%str3:~0,30%%
echo.
set str1=%%var:*:=%%%num%
set str3=%var:*:=%%nums%
echo 刪除var中的第一次出現的:號及其前面的所有字符
call echo %%str1:~0,15%% %%str3:~0,30%%
echo\
set str1=%%var:*"=ppp%%%num%
set str3=%var:*"=ppp%%nums%
echo 替換var中的第一次出現的^"號及其前面的所有字符為ppp
call echo %%str1:~0,15%% %%str3:~0,30%%
echo.
set str1=%%var:*\=ppp%%%num%
set str3=%var:*\=ppp%%nums%
echo 替換var中的第一次出現的\號及其前面的所有字符為ppp
call echo %%str1:~0,15%% %%str3:~0,30%%
echo.
set str1=%%var:*:=ppp%%%num%
set str3=%var:*:=ppp%%nums%
echo 替換var中的第一次出現的:號及其前面的所有字符為ppp
call echo %%str1:~0,15%% %%str3:~0,30%%
echo\
goto :eof

以上是“批處理中Set命令怎么用”這篇文章的所有內容，感謝各位的閱讀！相信大家都有了一定的了解，希望分享的內容對大家有所幫助，如果還想學習更多知識，歡迎關注億速云行業資訊頻道！