BAT批處理腳本的示例分析

這篇文章主要為大家展示了“BAT批處理腳本的示例分析”，內容簡而易懂，條理清晰，希望能夠幫助大家解決疑惑，下面讓小編帶領大家一起研究并學習一下“BAT批處理腳本的示例分析”這篇文章吧。

第一章 批處理基礎

第一節 常用批處理內部命令簡介

批處理定義：顧名思義，批處理文件是將一系列命令按一定的順序集合為一個可執行的文本文件，其擴展名為BAT或者CMD。這些命令統稱批處理命令。

小知識：可以在鍵盤上按下Ctrl+C組合鍵來強行終止一個批處理的執行過程。

了解了大概意思后,我們正式開始學習.先看一個簡單的例子!

@echo off
echo "歡迎來到億速云!"
pause

把上面的3條命令保存為文件test.bat或者test.cmd然后執行,
他就會在屏幕上顯示以下二行話:

歡迎來到億速云!

請按任意鍵繼續. . .
這就是一個簡單批處理文件了，這個批處理文件一共就用了2條命令 "echo" 和"pause" 還有一個特殊符號"@"
從上面這個簡單的批處理中,我們可以發現其實批處理就是運用一些含有特殊意義的符號和一些完成指定功能的命令組合而成,那么在批處理中有多少這樣的特殊符號和功能命令呢？我們現在就來仔細了解一下一些最常用的!

(以下內容來源網絡,請各位仔細閱讀,好進入下節的實例說明)

目錄

批處理的常見命令（未列舉的命令還比較多，請查閱幫助信息）

1、REM 和 ::
2、ECHO 和 @
3、PAUSE
4、ERRORLEVEL
5、TITLE
6、COLOR
7、mode 配置系統設備
8、GOTO 和 :
9、FIND
10、START
11、assoc 和 ftype
12、pushd 和 popd
13、CALL
14、shift
15、IF
16、setlocal 與 變量延遲
17、ATTRIB 顯示或更改文件屬性

介紹命令

1、REM 和 ::

REM為注釋命令，一般用來給程序加上注解，該命令后的內容不被執行，但能回顯。
其次, :: 也可以起到rem 的注釋作用, 而且更簡潔有效; 但有兩點需要注意：
第一, 任何以冒號:開頭的字符行, 在批處理中都被視作標號, 而直接忽略其后的所有內容。
有效標號：冒號后緊跟一個以字母數字開頭的字符串，goto語句可以識別。
無效標號：冒號后緊跟一個非字母數字的一個特殊符號，goto無法識別的標號，可以起到注釋作用，所以 :: 常被用作注釋符號，其實 :+ 也可起注釋作用。
第 二, 與rem 不同的是, ::后的字符行在執行時不會回顯, 無論是否用echo on打開命令行回顯狀態, 因為命令解釋器不認為他是一個有效的命令行, 就此點來看, rem 在某些場合下將比 :: 更為適用; 另外, rem 可以用于 config.sys 文件中。

行內注釋格式：%注釋內容% （不常用，慎用）

2、ECHO 和 @

@字符放在命令前將關閉該命令回顯，無論此時echo是否為打開狀態。

echo命令的作用列舉如下：
（1）打開回顯或關閉回顯功能
格式:echo [{ on|off }]
如果想關閉“ECHO OFF”命令行自身的顯示，則需要在該命令行前加上“@”。
（2）顯示當前ECHO設置狀態
格式:echo
（3）輸出提示信息
格式：ECHO 信息內容
上述是ECHO命令常見的三種用法，也是大家熟悉和會用的，但作為DOS命令淘金者你還應該知道下面的技巧：
（4）關閉DOS命令提示符
在DOS提示符狀態下鍵入ECHO OFF，能夠關閉DOS提示符的顯示使屏幕只留下光標，直至鍵入ECHO ON，提示符才會重新出現。
（5）輸出空行，即相當于輸入一個回車
格式：ECHO．
值得注意的是命令行中的“．”要緊跟在ECHO后面中間不能有空格，否則“．”將被當作提示信息輸出到屏幕。另外“．”可以用，：；”／[\]＋等任一符號替代。
命令ECHO．輸出的回車，經DOS管道轉向可以作為其它命令的輸入，比如echo.|time即相當于在TIME命令執行后給出一個回車。所以執行時系統會在顯示當前時間后，自動返回到DOS提示符狀態
（6）答復命令中的提問
格式：ECHO 答復語|命令文件名
上述格式可以用于簡化一些需要人機對話的命令（如：CHKDSK／F；FORMAT Drive:；del *.*）的操作，它是通過DOS管道命令把ECHO命令輸出的預置答復語作為人機對話命令的輸入。下面的例子就相當于在調用的命令出現人機對話時輸入“Y”回車：
C:>ECHO Y|CHKDSK/F
C:>ECHO Y|DEL A :*.*
（7）建立新文件或增加文件內容
格式：ECHO 文件內容>文件名
ECHO 文件內容>>文件名

例如：

C:>ECHO @ECHO OFF>AUTOEXEC.BAT建立自動批處理文件
C:>ECHO C:\CPAV\BOOTSAFE>>AUTOEXEC.BAT向自動批處理文件中追加內容
C:>TYPE AUTOEXEC.BAT顯示該自動批處理文件
@ECHO OFF
C:\CPAV\BOOTSAFE

（8）向打印機輸出打印內容或打印控制碼
格式：ECHO 打印機控制碼>;PRN
ECHO 打印內容>;PRN

下面的例子是向M－1724打印機輸入打印控制碼。＜Alt＞156是按住Alt鍵在小鍵盤鍵入156，類似情況依此類推：

C:>ECHO +156+42+116>;PRN（輸入下劃線命令FS＊t）
C:>ECHO [email=+155@]+155@>;PRN[/email]（輸入初始化命令ESC@）
C:>ECHO.>;PRN（換行）
（9）使喇叭鳴響
C:>ECHO ^G
“^G”是在dos窗口中用Ctrl＋G或Alt＋007輸入，輸入多個^G可以產生多聲鳴響。使用方法是直接將其加入批處理文件中或做成批處理文件調用。
這里的“^G”屬于特殊符號的使用，請看本文后面的章節

3、PAUSE

PAUSE，玩游戲的人都知道，暫停的意思
在這里就是停止系統命令的執行并顯示下面的內容。
例：

PAUSE

運行顯示：
請按任意鍵繼續. . .
要顯示其他提示語，可以這樣用：
Echo 其他提示語 & pause > nul

4、errorlevel

程序返回碼
echo %errorlevel%
每個命令運行結束，可以用這個命令行格式查看返回碼
用于判斷剛才的命令是否執行成功
默認值為0，一般命令執行出錯會設 errorlevel 為1

5、title

設置cmd窗口的標題
title 新標題 #可以看到cmd窗口的標題欄變了

6、COLOR

設置默認的控制臺前景和背景顏色。
COLOR [attr]
attr 指定控制臺輸出的顏色屬性
顏色屬性由兩個十六進制數字指定 -- 第一個為背景，第二個則為
前景。每個數字可以為以下任何值之一:
0 = 黑色 8 = 灰色
1 = 藍色 9 = 淡藍色
2 = 綠色 A = 淡綠色
3 = 湖藍色 B = 淡淺綠色
4 = 紅色 C = 淡紅色
5 = 紫色 D = 淡紫色
6 = 黃色 E = 淡黃色
7 = 白色 F = 亮白色
如果沒有給定任何參數，該命令會將顏色還原到 CMD.EXE 啟動時
的顏色。這個值來自當前控制臺窗口、/T 開關或
DefaultColor 注冊表值。
如果用相同的前景和背景顏色來執行 COLOR 命令，COLOR 命令
會將 ERRORLEVEL 設置為 1。
例如: "COLOR fc" 在亮白色上產生亮紅色

7、mode 配置系統設備

配置系統設備。
串行口:　　　 MODE COMm[:] [BAUD=b] [PARITY=p] [DATA=d] [STOP=s]
[to=on|off] [xon=on|off] [odsr=on|off]
[octs=on|off] [dtr=on|off|hs]
[rts=on|off|hs|tg] [idsr=on|off]
設備狀態: MODE [device] [/STATUS]
打印重定向:　　 MODE LPTn[:]=COMm[:]
選定代碼頁:　　 MODE CON[:] CP SELECT=yyy
代碼頁狀態:　　 MODE CON[:] CP [/STATUS]
顯示模式:　　 MODE CON[:] [COLS=c] [LINES=n]
擊鍵率:　 MODE CON[:] [RATE=r DELAY=d]
例：
mode con cols=113 lines=15 & color 9f
此命令設置DOS窗口大小：15行，113列

8、GOTO 和 :

GOTO會點編程的朋友就會知道這是跳轉的意思。
在批處理中允許以“:XXX”來構建一個標號，然后用GOTO XXX跳轉到標號:XXX處，然后執行標號后的命令。
例：

if {%1}=={} goto noparms
if "%2"=="" goto noparms

標簽的名字可以隨便起，但是最好是有意義的字符串啦，前加個冒號用來表示這個字符串是標簽，goto命令就是根據這個冒號（:）來尋找下一步跳到到那里。最好有一些說明這樣你別人看起來才會理解你的意圖啊。

例：

@echo off
:start
set /a var+=1
echo %var%
if %var% leq 3 GOTO start
pause

運行顯示：

1
2
3
4

9、find

在文件中搜索字符串。
FIND [/V] [/C] [/N] [/I] [/OFF[LINE]] "string" [[drive:][path]filename[ ...]]
/V 顯示所有未包含指定字符串的行。
/C 僅顯示包含字符串的行數。
/N 顯示行號。
/I 搜索字符串時忽略大小寫。
/OFF[LINE] 不要跳過具有脫機屬性集的文件。
"string" 指定要搜索的文字串，
[drive:][path]filename
指定要搜索的文件。
如果沒有指定路徑，FIND 將搜索鍵入的或者由另一命令產生的文字。
Find常和type命令結合使用

Type [drive:][path]filename | find "string" [>tmpfile] #挑選包含string的行
Type [drive:][path]filename | find /v "string" #剔除文件中包含string的行
Type [drive:][path]filename | find /c #顯示文件行數

以上用法將去除find命令自帶的提示語（文件名提示）

例：

@echo off
echo 111 >test.txt
echo 222 >>test.txt
find "111" test.txt
del test.txt
pause

運行顯示如下：

---------- TEST.TXT
111

請按任意鍵繼續. . .

例：

@echo off
echo 111 >test.txt
echo 222 >>test.txt
type test.txt|find "111" 
del test.txt
pause

運行顯示如下：

111

請按任意鍵繼續. . .

10、start 命令

批處理中調用外部程序的命令（該外部程序在新窗口中運行，批處理程序繼續往下執行，不理會外部程序的運行狀況），如果直接運行外部程序則必須等外部程序完成后才繼續執行剩下的指令

例：start explorer d:\

調用圖形界面打開D盤

11、assoc 和 ftype

文件關聯
assoc 設置'文件擴展名'關聯，關聯到'文件類型'
ftype 設置'文件類型'關聯，關聯到'執行程序和參數'
當你雙擊一個.txt文件時，windows并不是根據.txt直接判斷用 notepad.exe 打開
而是先判斷.txt屬于 txtfile '文件類型'
再調用 txtfile 關聯的命令行 txtfile=%SystemRoot%\system32\NOTEPAD.EXE %1
可以在"文件夾選項"→"文件類型"里修改這2種關聯
assoc #顯示所有'文件擴展名'關聯
assoc .txt #顯示.txt代表的'文件類型'，結果顯示 .txt=txtfile
assoc .doc #顯示.doc代表的'文件類型'，結果顯示 .doc=Word.Document.8
assoc .exe #顯示.exe代表的'文件類型'，結果顯示 .exe=exefile
ftype #顯示所有'文件類型'關聯
ftype exefile #顯示exefile類型關聯的命令行，結果顯示 exefile="%1" %*
assoc .txt=Word.Document.8
設置.txt為word類型的文檔，可以看到.txt文件的圖標都變了
assoc .txt=txtfile

恢復.txt的正確關聯

ftype exefile="%1" %*

恢復 exefile 的正確關聯
如果該關聯已經被破壞，可以運行 command.com ，再輸入這條命令

12、pushd 和 popd

切換當前目錄

@echo off
c: & cd\ & md mp3 #在 C:\ 建立 mp3 文件夾
md d:\mp4 #在 D:\ 建立 mp4 文件夾
cd /d d:\mp4 #更改當前目錄為 d:\mp4
pushd c:\mp3 #保存當前目錄，并切換當前目錄為 c:\mp3
popd #恢復當前目錄為剛才保存的 d:\mp4

一般用處不大，在當前目錄名不確定時，會有點幫助。（dos編程中很有用）

13、CALL

CALL命令可以在批處理執行過程中調用另一個批處理，當另一個批處理執行完后，再繼續執行原來的批處理
CALL command
調用一條批處理命令，和直接執行命令效果一樣，特殊情況下很有用，比如變量的多級嵌套，見教程后面。在批處理編程中，可以根據一定條件生成命令字符串，用call可以執行該字符串，見例子。
CALL [drive:][path]filename [batch-parameters]
調用的其它批處理程序。filename 參數必須具有 .bat 或 .cmd 擴展名。
CALL :label arguments
調用本文件內命令段，相當于子程序。被調用的命令段以標簽:label開頭
以命令goto :eof結尾。
另外，批腳本文本參數參照(%0、%1、等等)已如下改變:
批腳本里的 %* 指出所有的參數(如 %1 %2 %3 %4 %5 ...)
批參數(%n)的替代已被增強。您可以使用以下語法:（看不明白的直接運行后面的例子）
%~1 - 刪除引號(")，擴充 %1
%~f1 - 將 %1 擴充到一個完全合格的路徑名
%~d1 - 僅將 %1 擴充到一個驅動器號
%~p1 - 僅將 %1 擴充到一個路徑
%~n1 - 僅將 %1 擴充到一個文件名
%~x1 - 僅將 %1 擴充到一個文件擴展名
%~s1 - 擴充的路徑指含有短名
%~a1 - 將 %1 擴充到文件屬性
%~t1 - 將 %1 擴充到文件的日期/時間
%~z1 - 將 %1 擴充到文件的大小
%~PATH:1?查找列在PATH環境變量的目錄，并將PATH:1 - 在列在 PATH 環境變量中的目錄里查找 %1，
并擴展到找到的第一個文件的驅動器號和路徑。
%~ftza1 - 將 %1 擴展到類似 DIR 的輸出行。
在上面的例子中，%1 和 PATH 可以被其他有效數值替換。
%~ 語法被一個有效參數號碼終止。%~ 修定符不能跟 %*使用
注意：參數擴充時不理會參數所代表的文件是否真實存在，均以當前目錄進行擴展
要理解上面的知識，下面的例子很關鍵。

例：

@echo off
Echo 產生一個臨時文件 > tmp.txt
Rem 下行先保存當前目錄，再將c:\windows設為當前目錄
pushd c:\windows
Call :sub tmp.txt
Rem 下行恢復前次的當前目錄
Popd
Call :sub tmp.txt
pause
Del tmp.txt
exit
:sub
Echo 刪除引號： %~1
Echo 擴充到路徑： %~f1
Echo 擴充到一個驅動器號： %~d1
Echo 擴充到一個路徑： %~p1 
Echo 擴充到一個文件名： %~n1
Echo 擴充到一個文件擴展名： %~x1
Echo 擴充的路徑指含有短名： %~s1 
Echo 擴充到文件屬性： %~a1 
Echo 擴充到文件的日期/時間： %~t1 
Echo 擴充到文件的大小： %~z1 
Echo 擴展到驅動器號和路徑：%~dp1
Echo 擴展到文件名和擴展名：%~nx1
Echo 擴展到類似 DIR 的輸出行：%~ftza1
Echo.
Goto :eof

例：

set aa=123456
set cmdstr=echo %aa%
call %cmdstr%
pause

本例中如果不用call，而直接運行%cmdstr%，將顯示結果%aa%，而不是123456

14、shift

更改批處理文件中可替換參數的位置。
SHIFT [/n]
如果命令擴展名被啟用，SHIFT 命令支持/n 命令行開關；該命令行開關告訴
命令從第 n 個參數開始移位；n 介于零和八之間。例如:
SHIFT /2
會將 %3 移位到 %2，將 %4 移位到 %3，等等；并且不影響 %0 和 %1。

15、IF

IF 條件判斷語句，語法格式如下：
IF [NOT] ERRORLEVEL number command
IF [NOT] string1==string2 command
IF [NOT] EXIST filename command
下面逐一介紹，更詳細的分析請看后面章節。

(1) IF [NOT] ERRORLEVEL number command
IF ERRORLEVEL這個句子必須放在某一個命令的后面，執行命令后由IF ERRORLEVEL 來判斷命令的返回值。
Number的數字取值范圍0~255，判斷時值的排列順序應該由大到小。返回的值大于等于指定的值時，條件成立
例：

@echo off
dir c:
rem退出代碼為>=1就跳至標題1處執行，>=0就跳至標題0處執行
IF ERRORLEVEL 1 goto 1
IF ERRORLEVEL 0 goto 0
Rem 上面的兩行不可交換位置，否則失敗了也顯示成功。
:0
echo 命令執行成功！
Rem 程序執行完畢跳至標題exit處退出
goto exit
:1
echo 命令執行失敗！
Rem 程序執行完畢跳至標題exit處退出
goto exit
:exit
pause

運行顯示：命令執行成功！

(2) IF [NOT] string1==string2 command
string1和string2都為字符的數據，英文內字符的大小寫將看作不同，這個條件中的等于號必須是兩個（絕對相等的意思）
條件相等后即執行后面的command
檢測當前變量的值做出判斷，為了防止字符串中含有空格，可用以下格式
if [NOT] {string1}=={string2} command
if [NOT] [string1]==[string2] command
if [NOT] "string1"=="string2" command
這種寫法實際上將括號或引號當成字符串的一部分了，只要等號左右兩邊一致就行了，比如下面的寫法就不行：
if {string1}==[string2] command

(3) IF [NOT] EXIST filename command
EXIST filename為文件或目錄存在的意思
echo off
IF EXIST autoexec.bat echo 文件存在！
IF not EXIST autoexec.bat echo 文件不存在！
這個批處理大家可以放在C盤和D盤分別執行，看看效果

16、setlocal 與 變量延遲

本條內容引用[英雄出品]的批處理教程：
要想進階，變量延遲是必過的一關！所以這一部分希望你能認真看。
為了更好的說明問題，我們先引入一個例子。

例1:

@echo off
set a=4
set a=5 & echo %a%
pause

結果：4

解說：為什么是4而不是5呢？在echo之前明明已經把變量a的值改成5了？
讓我們先了解一下批處理運行命令的機制：
批 處理讀取命令時是按行讀取的（另外例如for命令等，其后用一對圓括號閉合的所有語句也當作一行），在處理之前要完成必要的預處理工作，這其中就包括對該 行命令中的變量賦值。我們現在分析一下例1，批處理在運行到這句“set a=5 & echo %a%”之前，先把這一句整句讀取并做了預處理——對變量a賦了值，那么%a%當然就是4了！（沒有為什么，批處理就是這樣做的。）
而為了能夠感知環境變量的動態變化，批處理設計了變量延遲。簡單來說，在讀取了一條完整的語句之后，不立即對該行的變量賦值，而會在某個單條語句執行之前再進行賦值，也就是說“延遲”了對變量的賦值。
那么如何開啟變量延遲呢？變量延遲又需要注意什么呢？舉個例子說明一下：

例2:

@echo off
setlocal enabledelayedexpansion
set a=4
set a=5 & echo !a!
pause

結果：5

解說：啟動了變量延遲，得到了正確答案。變量延遲的啟動語句是“setlocal enabledelayedexpansion”，并且變量要用一對嘆號“!!”括起來（注意要用英文的嘆號），否則就沒有變量延遲的效果。
分析一下例2，首先“setlocal enabledelayedexpansion”開啟變量延遲，然后“set a=4”先給變量a賦值為
4，“set a=5 & echo !a!”這句是給變量a賦值為5并輸出（由于啟動了變量延遲，所以批處理能夠感知到動態變化，即不是先給該行變量賦值，而是在運行過程中給變量賦值，因此此時a的值就是5了）。
再舉一個例子鞏固一下。

例3:

@echo off
setlocal enabledelayedexpansion
for /l %%i in (1,1,5) do (
set a=%%i
echo !a!
)
pause

結果：

1
2
3
4
5

解說：本例開啟了變量延遲并用“!!”將變量擴起來，因此得到我們預期的結果。如果不用變量延遲會出現什
么結果呢？結果是這樣的：
ECHO 處于關閉狀態。
ECHO 處于關閉狀態。
ECHO 處于關閉狀態。
ECHO 處于關閉狀態。
ECHO 處于關閉狀態。
即沒有感知到for語句中的動態變化。
提示：在沒有開啟變量延遲的情況下，某條命令行中的變量改變，必須到下一條命令才能體現。這一點也可以加以利用，看例子。
例：交換兩個變量的值，且不用中間變量

@echo off
::目的：交換兩個變量的值，但是不使用臨時變量
::Code by JM 2007-1-24 [email=CMD@XP]CMD@XP[/email]
::出處：http://www.cn-dos.net/forum/viewthread.php?tid=27078
set var1=abc
set var2=123
echo 交換前： var1=%var1% var2=%var2%
set var1=%var2%& set var2=%var1%
echo 交換后： var1=%var1% var2=%var2%
pause

17、ATTRIB 顯示或更改文件屬性

ATTRIB [+R|-R] [+A|-A] [+S|-S] [+H|-H] [[drive:] [path] filename] [/S [/D]]
+ 設置屬性。
- 清除屬性。
R 只讀文件屬性。
A 存檔文件屬性。
S 系統文件屬性。
H 隱藏文件屬性。
[drive:][path][filename]
指定要處理的文件屬性。
/S 處理當前文件夾及其子文件夾中的匹配文件。
/D 也處理文件夾。

例：

md autorun
attrib +a +s +h autorun

上面的命令將建立文件夾autorun，然后將其設為存檔、系統、隱藏屬性

第二節 常用特殊符號

1、@ 命令行回顯屏蔽符
2、% 批處理變量引導符
3、> 重定向符
4、>> 重定向符
5、<、>&、<& 重定向符
6、| 命令管道符
7、^ 轉義字符
8、& 組合命令
9、&& 組合命令
10、|| 組合命令
11、"" 字符串界定符
12、, 逗號
13、; 分號
14、() 括號
15、! 感嘆號
16、批處理中可能會見到的其它特殊標記符: （略）
CR(0D) 命令行結束符
Escape(1B) ANSI轉義字符引導符
Space(20) 常用的參數界定符
Tab(09) ; = 不常用的參數界定符
+ COPY命令文件連接符
* ? 文件通配符
/ 參數開關引導符
: 批處理標簽引導符

廢話少說，開講了

1、@ 命令行回顯屏蔽符

這個字符在批處理中的意思是關閉當前行的回顯。我們從前幾課知道
ECHO OFF可以關閉掉整個批處理命令的回顯，但不能關掉ECHO OFF這個命令，現在我們在ECHO OFF這個命令前加個@，就可以達到所有命令均不回顯的要求

2、% 批處理變量引導符

這個百分號嚴格來說是算不上命令的，它只是批處理中的參數而已（多個%一起使用的情況除外，以后還將詳細介紹）。
引用變量用%var%，調用程序外部參數用%1至%9等等
%0 %1 %2 %3 %4 %5 %6 %7 %8 %9 %*為命令行傳遞給批處理的參數
%0 批處理文件本身，包括完整的路徑和擴展名
%1 第一個參數
%9 第九個參數
%* 從第一個參數開始的所有參數
參數%0具有特殊的功能，可以調用批處理自身，以達到批處理本身循環的目的，也可以復制文件自身等等。
例：最簡單的復制文件自身的方法
copy %0 d:\wind.bat
小技巧：添加行內注釋
%注釋內容%（可以用作行內注釋，不能出現重定向符號和管道符號）
為什么這樣呢？此時“注釋內容”其實被當作變量，其值是空的，故只起注釋作用，不過這種用法容易出現語法錯誤，一般不用。

3、> 重定向符

輸出重定向命令
DOS的標準輸入輸出通常是在標準設備鍵盤和顯示器上進行的，利用重定向,可以方便地將輸入輸出改向磁盤文件或其它設備。其中:
1.大于號“>”將命令發送到文件或設備，例如打印機>prn。使用大于號“>”時，有些命令輸出(例如錯誤消息)不能重定向。
2.雙大于號“>>”將命令輸出添加到文件結尾而不刪除文件中已有的信息。
3.小于號“<”從文件而不是鍵盤上獲取命令所需的輸入。
4.>&符號將輸出從一個默認I/O流(stdout,stdin,stderr)重新定向到另一個默認I/O流。
例如，command >output_file 2>&1將處理command過程中的所有錯誤信息從屏幕重定向到標準文件輸出中。標準輸出的數值如下所示：

命令重定向的標準句柄

這個字符的意思是傳遞并且覆蓋，他所起的作用是將運行的結果傳遞到后面的范圍（后邊可以是文件，也可以是默認的系統控制臺）

在NT系列命令行中，重定向的作用范圍由整個命令行轉變為單個命令語句，受到了命令分隔符&,&&,||和語句塊的制約限制。
比如：

使用命令：echo hello >1.txt將建立文件1.txt，內容為”hello “（注意行尾有一空格）
使用命令：echo hello>1.txt將建立文件1.txt，內容為”hello“（注意行尾沒有空格）：

具體重定向實例請看這篇文章：DOS的重定向命令及在安全方面的應用

4、>> 重定向符

輸出重定向命令
這個符號的作用和>有點類似，但他們的區別是>>是傳遞并在文件的末尾追加，而>是覆蓋
用法同上
同樣拿1.txt做例子
使用命令：
echo hello > 1.txt
echo world >>1.txt
這時候1.txt 內容如下:
hello
world

5、<、>&、<& 重定向符

這三個命令也是管道命令，但它們一般不常用，你只需要知道一下就ok了，當然如果想仔細研究的話，可以自己查一下資料。(本人已查過，網上也查不到相關資料)
<，輸入重定向命令，從文件中讀入命令輸入，而不是從鍵盤中讀入。
@echo off
echo 2005-05-01>temp.txt
date <temp.txt
del temp.txt
這樣就可以不等待輸入直接修改當前日期
>&，將一個句柄的輸出寫入到另一個句柄的輸入中。
<&，剛好和>&相反，從一個句柄讀取輸入并將其寫入到另一個句柄輸出中。
常用句柄：0、1、2，未定義句柄：3—9
1>nul 表示禁止輸出正確的信息
2>nul 表示禁止輸出錯誤信息。
其中的1與2都是代表某個數據流輸入輸出的地址（NT CMD 稱之為句柄，MSDOS稱之為設備）。
句柄0：標準輸入stdin，鍵盤輸入
句柄1：標準輸出stdout，輸出到命令提示符窗口（console，代碼為CON）
句柄2：標準錯誤stderr，輸出到命令提示符窗口（console，代碼為CON）
其中的stdin可被<重定向，stdout可被>、>>重定向。
我們已經知道讀取文本中的內容可以用for命令，但如果只需要讀取第一行用for命令就有點麻煩。簡單的辦法如下:
@echo off
set /p str=<%0
echo %str%
pause
運行顯示批處理文件自身的第一行：@echo off

6、| 命令管道符

格式：第一條命令 | 第二條命令 [| 第三條命令...]
將第一條命令的結果作為第二條命令的參數來使用，記得在unix中這種方式很常見。
例如：
dir c:\|find "txt"
以上命令是：查找C：\所有，并發現TXT字符串。
FIND的功能請用 FIND /? 自行查看
在不使format的自動格式化參數時，我是這樣來自動格式化A盤的
echo y|format a: /s /q /v:system
用過format的都知道，再格盤時要輸入y來確認是否格盤，這個命令前加上echo y并用|字符來將echo y的結果傳給format命令
從而達到自動輸入y的目的
（這條命令有危害性，測試時請慎重）

7、^ 轉義字符

^是對特殊符號<,>,&的前導字符，在命令中他將以上3個符號的特殊功能去掉，僅僅只把他們當成符號而不使用他們的特殊意義。
比如
echo test ^>1.txt
結果則是：test > 1.txt
他沒有追加在1.txt里，呵呵。只是顯示了出來
另外，此轉義字符還可以用作續行符號。
舉個簡單的例子：

@echo off
echo 英雄^
是^
好^
男人
pause

不用多說，自己試一下就明白了。
為什么轉義字符放在行尾可以起到續行符的作用呢？原因很簡單，因為每行末尾還有一個看不見的符號，即回車符，轉義字符位于行尾時就讓回車符失效了，從而起到了續行的作用。

8、& 組合命令

語法：第一條命令 & 第二條命令 [& 第三條命令...]
&、&&、||為組合命令，顧名思義，就是可以把多個命令組合起來當一個命令來執行。這在批處理腳本里是允許的，而且用的非常廣泛。因為批處理認行不認命令數目。
這個符號允許在一行中使用2個以上不同的命令，當第一個命令執行失敗了，也不影響后邊的命令執行。
這里&兩邊的命令是順序執行的，從前往后執行。
比如：
dir z:\ & dir y:\ & dir c:\
以上命令會連續顯示z,y,c盤的內容，不理會該盤是否存在

9、&& 組合命令

語法：第一條命令 && 第二條命令 [&& 第三條命令...]
用這種方法可以同時執行多條命令，當碰到執行出錯的命令后將不執行后面的命令，如果一直沒有出錯則一直執行完所有命令
這個命令和上邊的類似，但區別是，第一個命令失敗時，后邊的命令也不會執行
dir z:\ && dir y:\ && dir c:\

10、|| 組合命令

語法：第一條命令 || 第二條命令 [|| 第三條命令...]
用這種方法可以同時執行多條命令，當一條命令失敗后才執行第二條命令，當碰到執行正確的命令后將不執行后面的命令，如果沒有出現正確的命令則一直執行完所有命令；

提示：組合命令和重定向命令一起使用必須注意優先級
管道命令的優先級高于重定向命令，重定向命令的優先級高于組合命令
問題：把C盤和D盤的文件和文件夾列出到a.txt文件中。看例：
dir c:\ && dir d:\ > a.txt
這 樣執行后a.txt里只有D盤的信息！為什么？因為組合命令的優先級沒有重定向命令的優先級高！所以這句在執行時將本行分成這兩部分：dir c:\和dir d:\ > a.txt，而并不是如你想的這兩部分：dir c:\ && dir d:\和> a.txt。要使用組合命令&&達到題目的要求，必須得這么寫：
dir c:\ > a.txt && dir d:\ >> a.txt
這樣，依據優先級高低，DOS將把這句話分成以下兩部分：dir c:\ > a.txt和dir d:\ >> a.txt。例十八中的幾句的差別比較特殊，值得好好研究體會一下。
當然這里還可以利用&命令（自己想一下道理哦）：
dir c:\ > a.txt & dir d:\ >> a.txt
[這個也可以用 dir c:\;d:\ >>a.txt 來實現]

11、"" 字符串界定符

雙引號允許在字符串中包含空格，進入一個特殊目錄可以用如下方法
cd "program files"
cd progra~1
cd pro*
以上三種方法都可以進入program files這個目錄

12、, 逗號

逗號相當于空格，在某些情況下“,”可以用來當做空格使
比如
dir,c:\

13、; 分號

分號，當命令相同時，可以將不同目標用；來隔離，但執行效果不變，如執行過程中發生錯誤，則只返回錯誤報告，但程序仍會執行。（有人說不會繼續執行，其實測試一下就知道了，只不過它的執行有個規則，請看下面的規則）
比如：
dir c:\;d:\;e:\;z:\
以上命令相當于
dir c:\
dir d:\
dir e:\
dir f:\
如果其中z盤不存在，運行顯示：系統找不到指定的路徑。然后終止命令的執行。
例：dir c:\;d:\;e:\1.txt
以上命令相當于
dir c:\
dir d:\
dir e:\1.txt
其中文件e:\1.txt不存在，但e盤存在，有錯誤提示，但命令仍會執行。

規則：(我是在操作系統是XP SP3,英文版下測試的)
1.如果目標路徑不存在，則整個語句都不執行，例如dir c:\;c:\dfdfdf\a.txt，則根本不會執行，因為我沒有c:\dfdfdf\這個目錄；
2.如果路徑存在，僅文件不存在，則會繼續執行，并且提示文件不存在的錯誤，例如：dir c:\;c:\temp\a.txt，我的目錄中有c:\temp\文件夾，但這個目錄下面沒有1.txt這個文件。
就說這些了!各位有什么意見請回貼!有什么疑問請到BAT交流區發貼!下一節改進!

14、() 括號

小括號在批處理編程中有特殊的作用，左右括號必須成對使用，括號中可以包括多行命令，這些命令將被看成一個整體，視為一條命令行。
括號在for語句和if語句中常見，用來嵌套使用循環或條件語句，其實括號()也可以單獨使用，請看例子。
例：
命令：echo 1 & echo 2 & echo 3
可以寫成：
(
echo 1
echo 2
echo 3
)
上面兩種寫法效果一樣，這兩種寫法都被視為是一條命令行。
注意：這種多條命令被視為一條命令行時，如果其中有變量，就涉及到變量延遲的問題。

15、! 感嘆號

沒啥說的，在變量延遲問題中，用來表示變量，即%var%應該表示為!var!，請看前面的setlocal命令介紹。

第二章 DOS循環：for命令詳解

講FOR之前呢,咋先告訴各位新手朋友,如果你有什么命令不懂,直接在CMD下面輸入:
name /? 這樣的格式來看系統給出的幫助文件,比如for /? 就會把FOR命令的幫助全部顯示出來!當然許多菜鳥都看不懂....所以才會有那么多批處理文章!!!!俺也照顧菜鳥,把FOR命令用我自己的方式說明下!
正式開始:

一、基本格式

FOR %%variable IN (set) DO command [command-parameters]
%%variable 指定一個單一字母表示可替換的參數。
(set) 指定一個或一組文件。可以使用通配符。
command 指定對每個文件執行的命令。
command-parameters
為特定命令指定參數或命令行開關。

參數:FOR有4個參數 /d /l /r /f 他們的作用我在下面用例子解釋
現在開始講每個參數的意思

二、參數 /d

FOR /D %%variable IN (set) DO command [command-parameters]
如果集中包含通配符，則指定與目錄名匹配，而不與文件
名匹配。
如果 Set (也就是我上面寫的 "相關文件或命令") 包含通配符（* 和 ?），將對與 Set 相匹配的每個目錄（而不是指定目錄中的文件組）執行指定的 Command。
這個參數主要用于目錄搜索,不會搜索文件,看這樣的例子

@echo off
for /d %%i in (c:\*) do echo %%i
pause

運行會把C盤根目錄下的全部目錄名字打印出來,而文件名字一個也不顯示!
在來一個,比如我們要把當前路徑下文件夾的名字只有1-3個字母的打出來

@echo off
for /d %%i in (???) do echo %%i
pause

這樣的話如果你當前目錄下有目錄名字只有1-3個字母的,就會顯示出來,沒有就不顯示了
這里解釋下*號和?號的作用,*號表示任意N個字符,而?號只表示任意一個字符
知道作用了,給大家個思考題目!

@echo off
for /d %%i in (window?) do echo %%i
pause

保存到C盤下執行,會顯示什么呢?自己看吧! 顯示：windows
/D參數只能顯示當前目錄下的目錄名字,這個大家要注意!

三、參數 /R

FOR /R [[drive:]path] %%variable IN (set) DO command [command-parameters]
檢查以 [drive:]path 為根的目錄樹，指向每個目錄中的
FOR 語句。如果在 /R 后沒有指定目錄，則使用當前
目錄。如果集僅為一個單點(.)字符，則枚舉該目錄樹。

遞歸

上面我們知道,/D只能顯示當前路徑下的目錄名字,那么現在這個/R也是和目錄有關,他能干嘛呢?放心他比/D強大多了!
他可以把當前或者你指定路徑下的文件名字全部讀取,注意是文件名字,有什么用看例子!
請注意2點：
1、set中的文件名如果含有通配符(？或*)，則列舉/R參數指定的目錄及其下面的所用子目錄中與set相符合的所有文件，無相符文件的目錄則不列舉。
2、相反，如果set中為具體文件名，不含通配符，則枚舉該目錄樹（即列舉該目錄及其下面的所有子目錄），而不管set中的指定文件是否存在。這與前面所說的單點（.）枚舉目錄樹是一個道理，單點代表當前目錄，也可視為一個文件。
例：

@echo off
for /r c:\ %%i in (*.exe) do echo %%i
pause

咱們把這個BAT保存到D盤隨便哪里然后執行,我會就會看到,他把C盤根目錄,和每個目錄的子目錄下面全部的EXE文件都列出來了!!!!
例：

@echo off
for /r %%i in (*.exe) do @echo %%i
pause

參數不一樣了吧!這個命令前面沒加那個C:\也就是搜索路徑,這樣他就會以當前目錄為搜索路徑,比如你這個BAT你把他放在d:\test目錄下執行,那么他就會把D:\test目錄和他下面的子目錄的全部EXE文件列出來!!!
例：

@echo off
for /r c:\ %%i in (boot.ini) do echo %%i
pause

運行本例發現枚舉了c盤所有目錄，為了只列舉boot.ini存在的目錄，可改成下面這樣：

@echo off
for /r c:\ %%i in (boot.ini) do if exist %%i echo %%i
pause

用這條命令搜索文件真不錯。。。。。。
這個參數大家應該理解了吧!還是滿好玩的命令!

四、參數 /L

FOR /L %%variable IN (start,step,end) DO command [command-parameters]
該集表示以增量形式從開始到結束的一個數字序列。
因此，(1,1,5) 將產生序列 1 2 3 4 5，(5,-1,1) 將產生
序列 (5 4 3 2 1)。
使 用迭代變量設置起始值 (Start#)，然后逐步執行一組范圍的值，直到該值超過所設置的終止值 (End#)。/L 將通過對 Start# 與 End# 進行比較來執行迭代變量。如果 Start# 小于 End#，就會執行該命令。如果迭代變量超過 End#，則命令解釋程序退出此循環。還可以使用負的 Step# 以遞減數值的方式逐步執行此范圍內的值。例如，(1,1,5) 生成序列 1 2 3 4 5，而 (5,-1,1) 則生成序列 (5 4 3 2 1)。語法是：
看著這說明有點暈吧!咱們看例子就不暈了!

@echo off
for /l %%i in (1,1,5) do @echo %%i
pause

保存執行看效果,他會打印從1 2 3 4 5 這樣5個數字
(1,1,5)這個參數也就是表示從1開始每次加1直到5終止!
等會暈,就打印個數字有P用...好的滿足大家,看這個例子

@echo off
for /l %%i in (1,1,5) do start cmd
pause

執行后是不是嚇了一跳,怎么多了5個CMD窗口,呵呵!如果把那個 (1,1,5)改成 (1,1,65535)會有什么結果,我先告訴大家,會打開65535個CMD窗口....這么多你不死機算你強!
當然我們也可以把那個start cmd改成md %%i 這樣就會建立指定個目錄了!!!名字為1-65535
看完這個被我賦予破壞性質的參數后,我們來看最后一個參數

五、參數 /F

\迭代及文件解析
使用文件解析來處理命令輸出、字符串及文件內容。使用迭代變量定義要檢查的內容或字符串，并使用各種options選項進一步修改解析方式。使用options令牌選項指定哪些令牌應該作為迭代變量傳遞。請注意：在沒有使用令牌選項時，/F 將只檢查第一個令牌。
文件解析過程包括讀取輸出、字符串或文件內容，將其分成獨立的文本行以及再將每行解析成零個或更多個令牌。然后通過設置為令牌的迭代變量值，調用 for 循環。默認情況下，/F 傳遞每個文件每一行的第一個空白分隔符號。跳過空行。

詳細的幫助格式為：

FOR /F ["options"] %%variable IN (file-set) DO command [command-parameters]
FOR /F ["options"] %%variable IN ("string") DO command [command-parameters]
FOR /F ["options"] %%variable IN ('command') DO command [command-parameters]

帶引號的字符串"options"包括一個或多個
指定不同解析選項的關鍵字。這些關鍵字為:
eol=c - 指一個行注釋字符的結尾(就一個)(備注：默認以使用；號為行首字符的為注釋行)
skip=n - 指在文件開始時忽略的行數，(備注：最小為1，n可以大于文件的總行數，默認為1。)
delims=xxx - 指分隔符集。這個替換了空格和跳格鍵的默認分隔符集。
tokens=x,y,m-n - 指每行的哪一個符號被傳遞到每個迭代
的 for 本身。這會導致額外變量名稱的分配。m-n
格式為一個范圍。通過 nth 符號指定 mth。如果
符號字符串中的最后一個字符星號，
那么額外的變量將在最后一個符號解析之后
分配并接受行的保留文本。經測試，該參數最多
只能區分31個字段。(備注：默認為1，則表示只顯示分割后的第一列的內容，最大是31，超過最大則無法表示)
usebackq - 使用后引號（鍵盤上數字1左面的那個鍵`）。
未使用參數usebackq時：file-set表示文件，但不能含有空格
雙引號表示字符串，即"string"
單引號表示執行命令，即'command'
使用參數usebackq時：file-set和"file-set"都表示文件
當文件路徑或名稱中有空格時，就可以用雙引號括起來
單引號表示字符串，即'string'
后引號表示命令執行，即`command`

以上是用for /?命令獲得的幫助信息，直接復制過來的，括號中的備注為我添加的說明。
暈慘了!我這就舉個例子幫助大家來理解這些參數!

For命令例1：****************************************

@echo off
rem 首先建立臨時文件test.txt
echo ;注釋行,這是臨時文件,用完刪除 >test.txt
echo 11段 12段 13段 14段 15段 16段 >>test.txt
echo 21段,22段,23段,24段,25段,26段 >>test.txt
echo 31段-32段-33段-34段-35段-36段 >>test.txt
FOR /F "eol=; tokens=1,3* delims=,- " %%i in (test.txt) do echo %%i %%j %%k
Pause
Del test.txt

運行顯示結果：

11段 13段 14段 15段 16段
21段 23段 24段,25段,26段
31段 33段 34段-35段-36段
請按任意鍵繼續. . .

為什么會這樣?我來解釋：
eol=; 分號開頭的行為注釋行
tokens=1,3* 將每行第1段,第3段和剩余字段分別賦予變量%%i，%%j，%%k
delims=,- （減號后有一空格）以逗號減號和空格為分隔符，空格必須放在最后

For命令例2：****************************************

@echo off
FOR /F "eol= delims=" %%i in (test.txt) do echo %%i
Pause

運行將顯示test.txt全部內容，包括注釋行，不解釋了哈。

For命令例3：****************************************
另外/F參數還可以以輸出命令的結果看這個例子

@echo off
FOR /F "delims=" %%i in ('net user') do @echo %%i
pause

這樣你本機全部帳號名字就出來了把擴號內的內容用兩個單引號引起來就表示那個當命令執行,FOR會返回命令的每行結果,加那個"delims=" 是為了讓我空格的行能整行顯示出來,不加就只顯示空格左邊一列!

基本上講完了FOR的基本用法了...如果你看過FOR的系統幫助,你會發現他下面還有一些特定義的變量,這些我先不講.大家因該都累了吧!你不累我累啊....
所謂文武之道，一張一弛，現休息一下。

第三章 FOR命令中的變量

FOR命令中有一些變量,他們的用法許多新手朋友還不太了解,今天給大家講解他們的用法!

先把FOR的變量全部列出來:
~I - 刪除任何引號(")，擴展 %I
%~fI - 將 %I 擴展到一個完全合格的路徑名
%~dI - 僅將 %I 擴展到一個驅動器號
%~pI - 僅將 %I 擴展到一個路徑
%~nI - 僅將 %I 擴展到一個文件名
%~xI - 僅將 %I 擴展到一個文件擴展名
%~sI - 擴展的路徑只含有短名
%~aI - 將 %I 擴展到文件的文件屬性
%~tI - 將 %I 擴展到文件的日期/時間
%~zI - 將 %I 擴展到文件的大小
%~$PATH:I - 查找列在路徑環境變量的目錄，并將 %I 擴展
到找到的第一個完全合格的名稱。如果環境變量名
未被定義，或者沒有找到文件，此組合鍵會擴展到
空字符串

我們可以看到每行都有一個大寫字母"I",這個I其實就是我們在FOR帶入的變量,我們FOR語句代入的變量名是什么,這里就寫什么.
比如:FOR /F %%z IN ('set') DO @echo %%z
這里我們代入的變量名是z那么我們就要把那個I改成z,例如%~fI改為%~fz
至于前面的%~p這樣的內容就是語法了!

好開始講解:

一、 ~I - 刪除任何引號(")，擴展 %I

這個變量的作用就如他的說明,刪除引號!
我們來看這個例子:
首先建立臨時文件temp.txt，內容如下

"1111
"2222"
3333"
"4444"44
"55"55"55

可建立個BAT文件代碼如下:

@echo off
echo ^"1111>temp.txt
echo "2222">>temp.txt
echo 3333^">>temp.txt
echo "4444"44>>temp.txt
echo ^"55"55"55>>temp.txt

rem 上面建立臨時文件，注意不成對的引號要加轉義字符^，重定向符號前不要留空格
FOR /F "delims=" %%i IN (temp.txt) DO echo %%~i
pause
del temp.txt

執行后,我們看CMD的回顯如下:
1111 #字符串前的引號被刪除了
2222 #字符串首尾的引號都被刪除了
3333" #字符串前無引號，后面的引號保留
4444"44 #字符串前面的引號刪除了，而中間的引號保留
55"55"55 #字符串前面的引號刪除了，而中間的引號保留
請按任意鍵繼續. . .
和之前temp.txt中的內容對比一下,我們會發現第1、2、5行的引號都消失了,這就是刪除引號~i的作用了!
刪除引號規則如下(BAT兄補充!)
1、若字符串首尾同時存在引號，則刪除首尾的引號；
2、若字符串尾不存在引號，則刪除字符串首的引號；
3、如果字符串中間存在引號，或者只在尾部存在引號，則不刪除。
龍卷風補充：無頭不刪，有頭連尾刪。

二、 %~fI - 將 %I 擴展到一個完全合格的路徑名

看例子:
把代碼保存放在隨便哪個地方,我這里就放桌面吧.
FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~fi
pause
執行后顯示內容如下
C:\Documents and Settings\Administrator\桌面\test.bat
C:\Documents and Settings\Administrator\桌面\test.vbs
當我把代碼中的 %%~fi直接改成%%i
FOR /F "delims==" %%i IN ('dir /b') DO @echo %%i
pause
執行后就會顯示以下內容：
test.bat
test.vbs
通過對比,我們很容易就看出沒有路徑了,這就是"將 %I 擴展到一個完全合格的路徑名"的作用
也就是如果%i變量的內容是一個文件名的話,他就會把這個文件所在的絕對路徑打印出來,而不只單單打印一個文件名,自己動手動實驗下就知道了!

三、 %~dI - 僅將 %I 擴展到一個驅動器號

看例子:
代碼如下,我還是放到桌面執行!

FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~di
pause

執行后我CMD里顯示如下
C:
C:
我桌面就兩個文件test.bat,test.vbs,%%~di作用是,如果變量%%i的內容是一個文件或者目錄名,他就會把他這文件
或者目錄所在的盤符號打印出來!

四、 %~pI - 僅將 %I 擴展到一個路徑

這個用法和上面一樣,他只打印路徑不打印文件名字

FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~pi
pause

我就不打結果了,大家自己看結果吧,下面幾個都是這么個用法,代碼給出來,大家自己看結果吧!

五、 %~nI - 僅將 %I 擴展到一個文件名

只打印文件名字

FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~ni
pause

六、 %~xI - 僅將 %I 擴展到一個文件擴展名

只打印文件的擴展名

FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~xi
pause

七、 %~sI - 擴展的路徑只含有短名
打印絕對短文件名

FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~si
pause

八、 %~aI - 將 %I 擴展到文件的文件屬性

打印文件的屬性

FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~ai
pause

九、 %~tI - 將 %I 擴展到文件的日期/時間

打印文件建立的日期

FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~ti
pause

十、 %~zI - 將 %I 擴展到文件的大小

打印文件的大小

FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~zi
pause

上面例子中的"delims=="可以改為"delims="，即不要分隔符

十一、 %~$PATH:I - 查找列在路徑環境變量的目錄

并將 %I 擴展到找到的第一個完全合格的名稱。如果環境變量名未被定義，或者沒有找到文件，此組合鍵會擴展到空字符串
這是最后一個,和上面那些都不一樣,我單獨說說!

然后在把這些代碼保存為批處理,放在桌面。

@echo off
FOR /F "delims=" %%i IN (“notepad.exe”) DO echo %%~$PATH:i
pause

龍卷風補充：上面代碼顯示結果為C:\WINDOWS\system32\notepad.exe
他的意思就在PATH變量里指定的路徑里搜索notepad.exe文件，如果有notepad.exe則會把他所在絕對路徑打印出來，沒有就打印一個錯誤！

好了,FOR的的變量就介紹到這了!

第四章 批處理中的變量

批處理中的變量,我把他分為兩類,分別為"系統變量"和"自定義變量"
我們現在來詳解這兩個變量!

一、系統變量

他們的值由系統將其根據事先定義的條件自動賦值,也就是這些變量系統已經給他們定義了值,
不需要我們來給他賦值,我們只需要調用而以! 我把他們全部列出來!

%ALLUSERSPROFILE% 本地 返回“所有用戶”配置文件的位置。
%APPDATA% 本地 返回默認情況下應用程序存儲數據的位置。
%CD% 本地 返回當前目錄字符串。
%CMDCMDLINE% 本地 返回用來啟動當前的 Cmd.exe 的準確命令行。
%CMDEXTVERSION% 系統 返回當前的“命令處理程序擴展”的版本號。
%COMPUTERNAME% 系統 返回計算機的名稱。
%COMSPEC% 系統 返回命令行解釋器可執行程序的準確路徑。
%DATE% 系統 返回當前日期。使用與 date /t 命令相同的格式。由 Cmd.exe 生成。有關
date 命令的詳細信息，請參閱 Date。
%ERRORLEVEL% 系統 返回上一條命令的錯誤代碼。通常用非零值表示錯誤。
%HOMEDRIVE% 系統 返回連接到用戶主目錄的本地工作站驅動器號。基于主目錄值而設置。用
戶主目錄是在“本地用戶和組”中指定的。
%HOMEPATH% 系統 返回用戶主目錄的完整路徑。基于主目錄值而設置。用戶主目錄是在“本地用戶和組”中指定的。
%HOMESHARE% 系統 返回用戶的共享主目錄的網絡路徑。基于主目錄值而設置。用戶主目錄是
在“本地用戶和組”中指定的。
%LOGONSERVER% 本地 返回驗證當前登錄會話的域控制器的名稱。
%NUMBER_OF_PROCESSORS% 系統 指定安裝在計算機上的處理器的數目。
%OS% 系統 返回操作系統名稱。Windows 2000 顯示其操作系統為 Windows_NT。
%PATH% 系統 指定可執行文件的搜索路徑。
%PATHEXT% 系統 返回操作系統認為可執行的文件擴展名的列表。
%PROCESSOR_ARCHITECTURE% 系統 返回處理器的芯片體系結構。值：x86 或 IA64 基于
Itanium
%PROCESSOR_IDENTFIER% 系統 返回處理器說明。
%PROCESSOR_LEVEL% 系統 返回計算機上安裝的處理器的型號。
%PROCESSOR_REVISION% 系統 返回處理器的版本號。
%PROMPT% 本地 返回當前解釋程序的命令提示符設置。由 Cmd.exe 生成。
%RANDOM% 系統 返回 0 到 32767 之間的任意十進制數字。由 Cmd.exe 生成。
%SYSTEMDRIVE% 系統 返回包含 Windows server operating system 根目錄（即系統根目錄）
的驅動器。
%SYSTEMROOT% 系統 返回 Windows server operating system 根目錄的位置。
%TEMP% 和 %TMP% 系統和用戶 返回對當前登錄用戶可用的應用程序所使用的默認臨時目錄。
有些應用程序需要 TEMP，而其他應用程序則需要 TMP。
%TIME% 系統 返回當前時間。使用與 time /t 命令相同的格式。由 Cmd.exe 生成。有關
time 命令的詳細信息，請參閱 Time。
%USERDOMAIN% 本地 返回包含用戶帳戶的域的名稱。
%USERNAME% 本地 返回當前登錄的用戶的名稱。
%USERPROFILE% 本地 返回當前用戶的配置文件的位置。
%WINDIR% 系統 返回操作系統目錄的位置。

這么多系統變量,我們如何知道他的值是什么呢?
在CMD里輸入 echo %WINDIR%
這樣就能顯示一個變量的值了!
舉個實際例子,比如我們要復制文件到當前帳號的啟動目錄里就可以這樣
copy d:\1.bat "%USERPROFILE%\「開始」菜單\程序\啟動\"
%USERNAME% 本地 返回當前登錄的用戶的名稱。 注意有空格的目錄要用引號引起來

另外還有一些系統變量,他們是代表一個意思,或者一個操作!
他們分別是%0 %1 %2 %3 %4 %5 ......一直到%9 還有一個%*
%0 這個有點特殊,有幾層意思,先講%1-%9的意思.
%1 返回批處理的第一個參數
%2 返回批處理的第二個參數
%3-%9依此推類
反回批處理參數?到底怎么個返回法?
我們看這個例子,把下面的代碼保存為test.BAT然后放到C盤下

@echo off
echo %1 %2 %3 %4
echo %1
echo %2
echo %3
echo %4

進入CMD,輸入cd c:\

然后輸入 test.bat 我是第一個參數 我是第二個參數 我是第三個參數 我是第四個參數
注意中間的空格,我們會看到這樣的結果:
我是第一個參數 我是第二個參數 我是第三個參數 我是第四個參數
我是第一個參數
我是第二個參數
我是第三個參數
我是第四個參數
對比下代碼,%1就是”我是第一個參數” %2就是”我是第二個參數”
怎么樣理解了吧!

這些%1和%9可以讓批處理也能帶參數運行,大大提高批處理功能!

還有一個%* 他是什么呢?他的作用不是很大,只是返回參數而已,不過他是一次返回全部參數的值,不用在輸入%1 %2來確定一個個的

例子

@echo off
echo %*

同樣保存為test.bat 放到C盤
進入CMD,輸入cd c:\
然后輸入 test.bat 我是第一個參數 我是第二個參數 我是第三個參數 我是第四個參數
可以看到他一次把全部參數都顯示出來了

好現在開始講那個比較特殊的%0

%0 這個不是返回參數的值了,他有兩層意思!
第一層意思:返回批處理所在絕對路徑
例子:

@echo off
echo %0
pause

保存為test.BAT放在桌面運行,會顯示如下結果
"C:\Documents and Settings\Administrator\桌面\test.bat"
他把當前批處理執行的所在路經打印出來了,這就是返回批處理所在絕對路徑的意思
第二層意思:無限循環執行BAT
例子:

@echo off
net user
%0

保存為BAT執行,他就會無限循環執行net user這條命令,直到你手動停止.
龍卷風補充：其實%0就是第一參數%1前面那個參數，當然就是批處理文件名（包括路徑）。
以上就是批處理中的一些系統變量,另外還有一些變量,他們也表示一些功能,
FOR命令中的那些就是,FOR變量已經說過,就不講了.

二、自定義變量

故名思意,自定義變量就是由我們來給他賦予值的變量
要使用自定義變量就得使用set命令了,看例子.

@echo off
set var=我是值
echo %var%
pause

保存為BAT執行,我們會看到CMD里返回一個 "我是值"
var為變量名,=號右變的是要給變量的值
這就是最簡單的一種設置變量的方法了
如果我們想讓用戶手工輸入變量的值,而不是在代碼里指定,可以用用set命令的/p參數
例子:

@echo off
set /p var=請輸入變量的值
echo %var%
pause

var變量名 =號右邊的是提示語,不是變量的值
變量的值由我們運行后自己用鍵盤輸入!

一、交互界面設計

沒啥說的，看看高手設計的菜單界面吧：

@echo off
cls
title 終極多功能修復
:menu
cls
color 0A
echo.
echo ==============================
echo 請選擇要進行的操作，然后按回車
echo ==============================
echo.
echo 1.網絡修復及上網相關設置,修復IE,自定義屏蔽網站
echo.
echo 2.病毒專殺工具，端口關閉工具,關閉自動播放
echo.
echo 3.清除所有多余的自啟動項目，修復系統錯誤
echo.
echo 4.清理系統垃圾,提高啟動速度
echo.
echo Q.退出
echo.
echo.
:cho
set choice=
set /p choice= 請選擇:
IF NOT "%choice%"=="" SET choice=%choice:~0,1%
if /i "%choice%"=="1" goto ip
if /i "%choice%"=="2" goto setsave
if /i "%choice%"=="3" goto kaiji
if /i "%choice%"=="4" goto clean
if /i "%choice%"=="Q" goto endd
echo 選擇無效，請重新輸入
echo.
goto cho

只要學完本教程前面的章節，上面的程序應該能看懂了。

二、if…else…條件語句

前面已經談到，DOS條件語句主要有以下形式
IF [NOT] ERRORLEVEL number command
IF [NOT] string1==string2 command
IF [NOT] EXIST filename command
增強用法：IF [/I] string1 compare-op string2 command
增強用法中加上/I就不區分大小寫了!
增強用法中還有一些用來判斷數字的符號：

EQU - 等于
NEQ - 不等于
LSS - 小于
LEQ - 小于或等于
GTR - 大于
GEQ - 大于或等于

上面的command命令都可以用小括號來使用多條命令的組合，包括else子句，組合命令中可以嵌套使用條件或循環命令。

例如:

IF EXIST filename (
del filename
) ELSE (
echo filename missing
)

也可寫成：
if exist filename (del filename) else (echo filename missing)
但這種寫法不適合命令太多或嵌套命令的使用。注意：else必須和if在同一行，或者和if最后的括號在同一行，如： ......) ELSE (......。在括號那換行程序認為是一條語句。

三、循環語句

1、指定次數循環
FOR /L %variable IN (start,step,end) DO command [command-parameters]

組合命令：
FOR /L %variable IN (start,step,end) DO (
Command1
Command2
……
)

2、對某集合執行循環語句。
FOR %%variable IN (set) DO command [command-parameters]

%%variable 指定一個單一字母可替換的參數。
(set) 指定一個或一組文件。可以使用通配符。
command 對每個文件執行的命令，可用小括號使用多條命令組合。

FOR /R [[drive:]path] %variable IN (set) DO command [command-parameters]

檢查以 [drive:]path 為根的目錄樹，指向每個目錄中的
FOR 語句。如果在 /R 后沒有指定目錄，則使用當前
目錄。如果集僅為一個單點(.)字符，則枚舉該目錄樹。

同前面一樣，command可以用括號來組合：
FOR /R [[drive:]path] %variable IN (set) DO (
Command1
Command2
……
commandn
)

3、條件循環
上面的循環結構是用for命令來實現的，for命令循環有一個缺點，就是整個循環被當作一條命令語句，涉及到變量延遲的問題。
利用goto語句和條件判斷，dos可以實現條件循環，很簡單啦，看例子：

例：

@echo off
set var=0
rem ************循環開始了
:continue
set /a var+=1
echo 第%var%次循環
if %var% lss 100 goto continue
rem ************循環結束了
echo 循環執行完畢
pause

例：

@echo off
set var=100
rem ************循環開始了
:continue
echo 第%var%次循環
set /a var-=1
if %var% gtr 0 goto continue
rem ************循環結束了
echo 循環執行完畢
pause

四、子程序

在批處理程序中可以調用外部可運行程序，比如exe程序，也可調用其他批處理程序，這些也可以看作子程序，但是不夠方便，如果被調用的程序很多，就顯得不夠簡明了，很繁瑣。
在windowsXP中，批處理可以調用本程序中的一個程序段，相當于子程序，這些子程序一般放在主程序后面。

子程序調用格式：
CALL :label arguments

子程序語法：
:label
command1
command2
......
commandn
goto :eof

在子程序段中，參數%0指標簽:label

子過程一般放在最后，并且注意在主程序最后要加上exit或跳轉語句，避免錯誤的進入子過程。

子程序和主程序中的變量都是全局變量，其作用范圍都是整個批處理程序。

傳至子程序的參數在call語句中指定，在子程序中用%1、%2至%9的形式調用，而子程序返回主程序的數據只需在調用結束后直接引用就可以了，當然也可以指定返回變量，請看下面的例子。

子程序例1：

@echo off
call :sub return
echo 子程序返回值：%return%
pause
goto :eof

:sub
set %1=你好
goto :eof

運行結果：你好

子程序例2：設計一個求多個整數相加的子程序

@echo off
set sum=0
call :sub 10 20 35 40 50
echo 數據求和結果：%sum%
pause
goto :eof

:sub
rem 參數1為返回變量名稱
set /a sum+=%1
shift /1 
if not "%1"=="" goto sub
goto :eof

運行結果：155

五、用ftp命令實現自動下載

ftp是常用的下載工具，ftp界面中有40多個常用命令，自己學習了，不介紹了。這里介紹如何用dos命令行調用ftp命令，實現ftp自動登錄，并上傳下載，并自動退出ftp程序。
其實可以將ftp命令組合保存為一個文本文件，然后用以下命令調用即可。

ftp -n -s:[[drive:]path]filename

上面的filename為ftp命令文件，包括登錄IP地址，用戶名、密碼、操作命令等
例：

open 90.52.8.3 ＃打開ip
user iware ＃用戶為iware
password8848 ＃密碼
bin ＃二進制傳輸模式
prompt
cd tmp1 ＃切換至iware用戶下的tmp1目錄
pwd
lcd d:\download ＃本地目錄
mget * ＃下載tmp1目錄下的所有文件
bye ＃退出ftp

六、用7-ZIP實現命令行壓縮和解壓功能

語法格式：（詳細情況見7-zip幫助文件，看得頭暈可以跳過，用到再學）
7z <command> [<switch>...] <base_archive_name> [<arguments>...]

7z.exe的每個命令都有不同的參數<switch>,請看幫助文件
<base_archive_name>為壓縮包名稱
<arguments>為文件名稱，支持通配符或文件列表

其中，7z是至命令行壓縮解壓程序7z.exe，<command>是7z.exe包含的命令，列舉如下：

a： Adds files to archive. 添加至壓縮包
a命令可用參數：
-i (Include)
-m (Method)
-p (Set Password)
-r (Recurse)
-sfx (create SFX)
-si (use StdIn)
-so (use StdOut)
-ssw (Compress shared files)
-t (Type of archive)
-u (Update)
-v (Volumes)
-w (Working Dir)
-x (Exclude)

b： Benchmark
d： Deletes files from archive. 從壓縮包中刪除文件
d命令可用參數：
-i (Include)
-m (Method)
-p (Set Password)
-r (Recurse)
-u (Update)
-w (Working Dir)
-x (Exclude)

e： Extract解壓文件至當前目錄或指定目錄
e命令可用參數：
-ai (Include archives)
-an (Disable parsing of archive_name)
-ao (Overwrite mode)
-ax (Exclude archives)
-i (Include)
-o (Set Output Directory)
-p (Set Password)
-r (Recurse)
-so (use StdOut)
-x (Exclude)
-y (Assume Yes on all queries)

l： Lists contents of archive.
t： Test
u： Update

x： eXtract with full paths用文件的完整路徑解壓至當前目錄或指定目錄
x命令可用參數：
-ai (Include archives)
-an (Disable parsing of archive_name)
-ao (Overwrite mode)
-ax (Exclude archives)
-i (Include)
-o (Set Output Directory)
-p (Set Password)
-r (Recurse)
-so (use StdOut)
-x (Exclude)
-y (Assume Yes on all queries)

七、調用VBScript程序

使用 Windows 腳本宿主，可以在命令提示符下運行腳本。CScript.exe 提供了用于設置腳本屬性的命令行開關。

用法：CScript 腳本名稱 [腳本選項...] [腳本參數...]
選項：
//B 批模式：不顯示腳本錯誤及提示信息
//D 啟用 Active Debugging
//E:engine 使用執行腳本的引擎
//H:CScript 將默認的腳本宿主改為 CScript.exe
//H:WScript 將默認的腳本宿主改為 WScript.exe （默認）
//I 交互模式（默認，與 //B 相對)
//Job:xxxx 執行一個 WSF 工作
//Logo 顯示徽標（默認）
//Nologo 不顯示徽標：執行時不顯示標志
//S 為該用戶保存當前命令行選項
//T:nn 超時設定秒：允許腳本運行的最長時間
//X 在調試器中執行腳本
//U 用 Unicode 表示來自控制臺的重定向 I/O

“腳本名稱”是帶有擴展名和必需的路徑信息的腳本文件名稱，如d:/admin/vbscripts/chart.vbs。
“腳本選項和參數”將傳遞給腳本。腳本參數前面有一個斜杠 (/)。每個參數都是可選的；但不能在未指定腳本名稱的情況下指定腳本選項。如果未指定參數，則 CScript 將顯示 CScript 語法和有效的宿主參數。

八、將批處理轉化為可執行文件

由于批處理文件是一種文本文件，任何人都可以對其進行隨便編輯，不小心就會把里面的命令破壞掉，所以如果將其轉換成.com格式的可執行文件，不僅執行效率會大大提高，而且不會破壞原來的功能，更能將優先級提到最高。Bat2Com就可以完成這個轉換工作。
小 知識：在DOS環境下，可執行文件的優先級由高到低依次為.com>.exe>.bat>.cmd，即如果在同一目錄下存在文件名相同 的這四類文件，當只鍵入文件名時，DOS執行的是name.com，如果需要執行其他三個文件，則必須指定文件的全名，如name.bat。

這是一個只有5.43K大小的免費綠色工具，可以運行在純DOS或DOS窗口的命令行中，用法：Bat2Com
FileName，這樣就會在同一目錄下生成一個名為FileNme.com的可執行文件，執行的效果和原來的.bat文件一樣。

九、時間延遲

本條參考引用[英雄]教程
什么是時間延遲？顧名思義，就是執行一條命令后延遲一段時間再進行下一條命令。
延遲的應用見下節：“模擬進度條”。
1、利用ping命令延時
例：

@echo off
echo 延時前：%time%
ping /n 3 127.0.0.1 >nul
echo 延時后：%time%
pause

解說：用到了ping命令的“/n”參數，表示要發送多少次請求到指定的ip。本例中要發送3次請求到本機的ip（127.0.0.1）。127.0.0.1可簡寫為127.1。“>nul”就是屏蔽掉ping命令所顯示的內容。

2、利用for命令延時

例：

@echo off
echo 延時前：%time%
for /l %%i in (1,1,5000) do echo %%i>nul
echo 延時后：%time%
pause

解說：原理很簡單，就是利用一個計次循環并屏蔽它所顯示的內容來達到延時的目的。

3、利用vbs延遲函數，精確度毫秒，誤差1000毫秒內

例：

@echo off
echo %time%
call :delay 5000
echo %time%
pause

exit
:delay
echo WScript.Sleep %1>delay.vbs
CScript //B delay.vbs
del delay.vbs
goto :eof

運行顯示：

10:44:06.45
10:44:11.95
請按任意鍵繼續. . .

上面的運行結果顯示實際延時了5500毫秒，多出來的500毫秒時建立和刪除臨時文件所耗費的時間。誤差在一秒之內。

4、僅用批處理命令實現任意時間延遲，精確度10毫秒，誤差50毫秒內

僅用批處理命令就可以實現延遲操作。

例：

@echo off
set /p delay=請輸入需延遲的毫秒數：
set TotalTime=0
set NowTime=%time%
::讀取起始時間，時間格式為：13:01:05.95
echo 程序開始時間：%NowTime%
:delay_continue
set /a minute1=1%NowTime:~3,2%-100
::讀取起始時間的分鐘數
set /a second1=1%NowTime:~-5,2%%NowTime:~-2%0-100000
::將起始時間的秒數轉為毫秒
set NowTime=%time%
set /a minute2=1%NowTime:~3,2%-100
:: 讀取現在時間的分鐘數
set /a second2=1%NowTime:~-5,2%%NowTime:~-2%0-100000
::將現在時間的秒數轉為毫秒
set /a TotalTime+=(%minute2%-%minute1%+60)%%60*60000+%second2%-%second1%
if %TotalTime% lss %delay% goto delay_continue
echo 程序結束時間：%time%
echo 設定延遲時間：%delay%毫秒
echo 實際延遲時間：%TotalTime%毫秒
pause

運行顯示：

請輸入需延遲的毫秒數：6000
程序開始時間：15:32:16.37
程序結束時間：15:32:22.37
設定延遲時間：6000毫秒
實際延遲時間：6000毫秒
請按任意鍵繼續. . .

實現原理：首先設定要延遲的毫秒數，然后用循環累加時間，直到累加時間大于等于延遲時間。

誤差：windows系統時間只能精確到10毫秒，所以理論上有可能存在10毫秒誤差。
經測試，當延遲時間大于500毫秒時，上面的延遲程序一般不存在誤差。當延遲時間小于500毫秒時，可能有幾十毫秒誤差，為什么？因為延遲程序本身也是有運行時間的，同時系統時間只能精確到10毫秒。

為了方便引用，可將上面的例子改為子程序調用形式：

@echo off
echo 程序開始時間：%Time%
call :delay 10
echo 實際延遲時間：%totaltime%毫秒
echo 程序結束時間：%time%
pause
exit

::-----------以下為延時子程序--------------------
:delay
@echo off
if "%1"=="" goto :eof
set DelayTime=%1
set TotalTime=0
set NowTime=%time%
::讀取起始時間，時間格式為：13:01:05.95
:delay_continue
set /a minute1=1%NowTime:~3,2%-100
set /a second1=1%NowTime:~-5,2%%NowTime:~-2%0-100000
set NowTime=%time%
set /a minute2=1%NowTime:~3,2%-100
set /a second2=1%NowTime:~-5,2%%NowTime:~-2%0-100000
set /a TotalTime+=(%minute2%-%minute1%+60)%%60*60000+%second2%-%second1%
if %TotalTime% lss %DelayTime% goto delay_continue
goto :eof

十、模擬進度條

下面給出一個模擬進度條的程序。如果將它運用在你自己的程序中，可以使你的程序更漂亮。

@echo off
mode con cols=113 lines=15 &color 9f
cls
echo.
echo 程序正在初始化. . . 
echo.
echo ┌──────────────────────────────────────┐
set/p= ■<nul
for /L %%i in (1 1 38) do set /p a=■<nul&ping /n 1 127.0.0.1>nul
echo 100%%
echo └──────────────────────────────────────┘
pause

解說：“set /p a=■<nul”的意思是：只顯示提示信息“■”且不換行，也不需手工輸入任何信息，這樣可以使每個“■”在同一行逐個輸出。“ping /n 0 127.1>nul”是輸出每個“■”的時間間隔，ping /n 0表示不執行這個命令，所以會比ping出去的時間更短，也就是即每隔多少時間最短輸出一個“■”。當然你也可以改為1或2或3等使時間延長

PS:上面的代碼執行太快了，并且第一個出現的節奏和后面的不協調，我稍微修改了點，如下：

echo.
echo ┌──────────────────────────────────────┐
ping 127.0.0.1 >nul /n 1 & set /p=<nul 
for /L %%i in (1 1 39) do set /p a=■<nul & ping /n 1 127.0.0.1>nul
echo 100%%
echo └──────────────────────────────────────┘
pause

十一、特殊字符的輸入及應用

開始 -> 運行 -> 輸入cmd -> edit -> ctrl+p（意思是允許輸入特殊字符）-> 按ctrl+a將會顯示笑臉圖案。

（如果要繼續輸入特殊字符請再次按ctrl+p，然后ctrl+某個字母）

以上是特殊字符的輸入方法，選自[英雄]教程，很管用的。也就是用編輯程序edit輸入特殊字符，然后保存為一文本文件，再在windows下打開此文件，復制其中的特殊符號即可。

一些簡單的特殊符號可以在dos命令窗口直接輸入，并用重定向保存為文本文件。
例：

C:>ECHO ^G>temp.txt
“^G”是用Ctrl＋G或Alt＋007輸入(按住Alt后，只能按小鍵盤的數字)，輸入多個^G可以產生多聲鳴響。

特殊字符的應用也很有意思，這里僅舉一例：退格鍵(輸入方法：開始 -> 運行 -> 輸入cmd -> edit -> ctrl+p ->退格鍵)

退格鍵表示刪除左邊的字符，此鍵不能在文檔中正常輸入，但可以通過edit編輯程序錄入并復制出來。即“”。

利用退格鍵，配合空格覆蓋，可以設計閃爍文字效果

例：文字閃爍，可以使用Ctrl+C組合鍵來強行終運行

@echo off
:start
set/p=床前明月光<nul
::顯示文字，光標停于行尾
ping -n 0 127.0.0.1>nul
::設置延遲時間

set /p a=<nul
:: 輸出一些退格符將光標置于該行的最左端（退格符的數量可以自己調整）。

ping -n 0 127.0.0.1>nul
::設置延遲時間

set /p a= <nul
::輸出空格將之前輸出的文字覆蓋掉。

set /p a=<nul
::再次輸出退格符將光標置于該行的最左端，這里的退格符數量一定不能比前面的

空格數少，否則光標不能退到最左端。

ping -n 0 127.0.0.1>nul
::設置延遲時間

goto start

解說：主要是利用set命令的/p，表示后等號面的字符都是提示字符，然后在用退格鍵，讓光標置于該行的最左端，但是原來的文字還在，然后使用空格作為輸入提示符，所以就會覆蓋前面的文字，然后再次輸出退格符將光標置于該行的最左端，循環執行。如果你把ping命令的次數改為4，使延遲增長，就能看到光標的位置變化了。

例：輸出唐詩一首，每行閃動多次

@echo off
setlocal enabledelayedexpansion

set str=床前明月光 疑是地上霜 舉頭望明月 低頭思故鄉
::定義字符串str
for %%i in (%str%) do (
rem 由于str中含有空格，則以空格為分隔符將str中的每一個部分依次賦給變量%%i。
set char=%%i
echo.
echo.
for /l %%j in (0,1,5) do (
set/p=!char:~%%j,1!<nul
rem 依次取出變量char中的每一個字符，并顯示。
ping -n 0 127.0.0.1>nul
rem 設置輸出每個字符的時間延遲。
)
call :hero %%i
)
pause>nul
exit

:hero
for /l %%k in (1,1,10) do (
ping /n 0 127.0.0.1>nul
set /p a=<nul
set /p a= <nul
set /p a=<nul
ping /n 0 127.0.0.1>nul
set /p a=%1<nul
)
::文字閃動
goto :eof

十二、隨機數（%random%）的應用技巧

%RANDOM% 系統變量 返回 0 到 32767 之間的任意十進制數字。由 Cmd.exe 生成。

2的15次方等于32768，上面的0～32767實際就是15位二進制數的范圍。

那么，如何獲取100以內的隨機數呢？很簡單，將%RANDOM%按100進行求余運算即可，見例子。

例：生成5個100以內的隨機數

@echo off
setlocal enabledelayedexpansion
for /L %%i in (1 1 5) do (
set /a randomNum=!random!%%100
echo 隨機數：!randomNum!
)
pause

運行結果：（每次運行不一樣）
隨機數：91
隨機數：67
隨機數：58
隨機數：26
隨機數：20
請按任意鍵繼續. . .

求余數運算set /a randomNum=!random!%%100中的100可以是1～32768之間的任意整數。

總結：利用系統變量%random%，求余數運算%%，字符串處理等，可以實現很多隨機處理。

通過上面的學習，我們知道，%random%可以產生0到32767之間的隨機數，但是，如何才能得到一定范圍內的隨機數呢？
我們可以使用通用的算法公式如下：
　　通用的公式%random%%%(max-min+1)+min來產生[min,max]區間里的隨機數，
注：批處理中求模得用兩個%%符號。
　　比如，我們想獲得4到12之間的隨機數，就可以這樣來使用，代碼如下：

@REM 產生10個[4,12]間的隨機數 
@echo off 
REM 啟用延遲環境變量擴展 
setlocal enabledelayedexpansion 
REM 設置隨機數的最小和最大值以及求模用的變量 
set min=4 
set max=12 
set /a mod=!max!-!min!+1

for /l %%i in (1,1,10) do ( 
REM 產生[min,max]之間的隨機數 
set /a r=!random!%%!mod!+!min! 
echo. 
echo 隨機數%%i：!r!)

詳細出處參考：//www.5655pk.com/article/36489.htm

思考題目：生成給定位數的隨機密碼
解答思路：將26個英文字母或10數字以及其它特殊字符組成一個字符串，隨機抽取其中的若干字符。

參考答案1：（簡單）

@echo off
call :randomPassword 5 pass1 pass2
echo %pass1% %pass2% 
pause
exit

:randomPassword
::---------生成隨機密碼
::---------%1為密碼長度，%2及以后為返回變量名稱
::---------for命令最多只能區分31個字段
@echo off
set password_len=%1
if not defined password_len goto :eof
if %password_len% lss 1 goto :eof
set wordset=a b c d e f g h i j k l m n o p q r s t u v w x y z
set return=
set num=0
:randomPassword1
set /a num+=1
set /a numof=%random%%%26+1
for /f "tokens=%numof% delims= " %%i in ("%wordset%") do set return=%return%%%i
if %num% lss %password_len% goto randomPassword1
if not "%2"=="" set %2=%return%
shift /2
if not "%2"=="" goto randomPassword
goto :eof

參考答案2：（最優）

@echo off
call :randomPassword 6 pass1 pass2 pass3
echo %pass1% %pass2% %pass3%
pause
exit

:randomPassword
::---------生成隨機密碼
::---------%1為密碼長度，%2及以后為返回變量名稱
::---------goto循環、變量嵌套、命令嵌套
@echo off
if "%1"=="" goto :eof
if %1 lss 1 goto :eof
set password_len=%1
set return=
set wordset=abcdefghijklmnopqrstuvwxyz023456789_
::---------------------------循環
:randomPassword1
set /a numof=%random%%%36 ::---生成0-35之間的隨即數
call set return=%return%%%wordset:~%numof%,1%% ::---在wordset變量中，從的隨即生成的0-35的下一個取出一個字符
set /a password_len-=1
if %password_len% gtr 0 goto randomPassword1
::---------------------------循環
if not "%2"=="" set %2=%return%
shift /2
if not "%2"=="" goto randomPassword
goto :eof

說明：本例涉及到變量嵌套和命令嵌套的應用，見后。

十三、變量嵌套 與 命令嵌套

和其它編程語言相比，dos功能顯得相對簡單，要實現比較復雜的功能，需要充分運用各種技巧，變量嵌套與命令嵌套就是此類技巧之一。

先復習一下前面的“字符串截取”的關鍵內容：

**********************************************
截取功能統一語法格式為：%a:~[m[,n]]%
**********************************************
方括號表示可選，%為變量標識符，a為變量名，不可少，冒號用于分隔變量名和說明部分，符號～可以簡單理解為“偏移”即可，m為偏移量（缺省為0），n為截取長度（缺省為全部）。

百分號如果需要當成單一字符，必須寫成%%

以上是dos變量處理的通用格式，如果其中的m、n為變量，那么這種情況就是變量嵌套了。

比如設變量word為“abcdefghij”，變量num為“123456789”
%word:~4,1%為e，其中4可以從變量num中取值，即%num:~3,1%，寫成組合形式如下：
%word:~%num:~3,1%,1% 經測試這種寫法不能正確執行，寫成%word:~(%num:~3,1%),1%同樣不行，那么，怎么實現這種變量嵌套呢？這就必須結合命令嵌套。

什么是命令嵌套呢？簡單的說，首先用一條dos命令生成一個字符串，而這個字符串是另一條dos命令，用call語句調用字符串將其執行，從而得到最終結果。

例：用call語句實現命令嵌套

@echo off
set str1=aaa echo ok bbb
echo 初始字符串：%str1%
echo 生成命令字符串如下：
echo %str1:~4,7%
echo 運行命令字符串生成最終結果為：
call %str1:~4,7%
pause

運行顯示：
初始字符串：aaa echo ok bbb
生成命令字符串如下：
echo ok
運行命令字符串生成最終結果為：
ok
請按任意鍵繼續. . .

以上是“BAT批處理腳本的示例分析”這篇文章的所有內容，感謝各位的閱讀！相信大家都有了一定的了解，希望分享的內容對大家有所幫助，如果還想學習更多知識，歡迎關注億速云行業資訊頻道！