.版本 2
.常量 常量1, "<文本長度: 139>", , "accttype": "(.*?)"[\s\S]*?"balance": "(.*?)"[\s\S]*?"info": "(.*?)"[\s\S]*?"pay": "(.*?)"[\s\S]*?"save": "(.*?)"[\s\S]*?"tranday": "(.*?)"
.常量 常量2, "<文本長度: 15>", , "list": [ ] } }

.版本 2
.全局變量 Cookie, 文本型
.全局變量 G_tk, 文本型
.全局變量 QQ號碼, 文本型

.版本 2
.支持庫 HtmlView
.程序集 窗口程序集_啟動窗口
.子程序 _超文本瀏覽框1_跳轉完畢
.如果真 (超文本瀏覽框1.地址 ＝ “https://my.pay.qq.com/account/account_qdqb_trade_record.shtml”)
  Cookie ＝ 網頁_取Cookie (“qq.com”)
  G_tk ＝ 計算G_tk (文本_取出中間文本 (Cookie, “skey=”, “;”))
  QQ號碼 ＝ 文本_取出中間文本 (Cookie, “uin=o”, “;”)
  載入 (窗口1, , 假)
  銷毀 ()
.如果真結束
.子程序 計算G_tk, 文本型
.參數 skey, 文本型
.局部變量 hash, 整數型
.局部變量 計次, 整數型
hash ＝ 5381
.變量循環首 (1, 取文本長度 (skey), 1, 計次)
  hash ＝ hash ＋ hash × 求次方 (2, 5) ＋ 取字節集數據 (編碼_Ansi到Unicode (取文本中間 (skey, 計次, 1)), 3, )
.變量循環尾 ()
返回 (到文本 (位與 (hash, 進制_十六到十 (“7fffffff”))))
.子程序 __啟動窗口_創建完畢

.版本 2
.支持庫 EThread
.支持庫 spec
.支持庫 iext
.程序集 窗口程序集_窗口1
.子程序 _窗口1_創建完畢
截止編輯框.內容 ＝ 到文本 (取年份 (取現行時間 ())) ＋ “-” ＋ 到文本 (取月份 (取現行時間 ())) ＋ “-” ＋ 到文本 (取日 (取現行時間 ()))
窗口1.標題 ＝ 窗口1.標題 ＋ “ [” ＋ QQ號碼 ＋ “]”
.子程序 _查詢按鈕_被單擊
.判斷開始 (查詢按鈕.標題 ＝ “開始查詢”)
  導出按鈕.禁止 ＝ 假
  查詢按鈕.禁止 ＝ 真
  啟動線程 (&子程序_開始查詢, , )
.默認
  查詢按鈕.標題 ＝ “開始查詢”
.判斷結束
.子程序 子程序_開始查詢
.局部變量 返回文本, 文本型
.局部變量 共記錄, 文本型
.局部變量 正則, 正則表達式類
.局部變量 i, 整數型
.局部變量 M, 整數型
.局部變量 頁數, 整數型, 靜態
返回文本 ＝ 網頁_訪問S (“http://my.pay.qq.com/cgi-bin/personal/account_tradeinfo.cgi?coin_type=0&start_date=” ＋ 起始編輯框.內容 ＋ “&end_date=” ＋ 截止編輯框.內容 ＋ “&page_no=1&channel=qdqb&per=10&extcode=&t=” ＋ 時間_取隨機時間戳 (), , , Cookie)
調試輸出 (返回文本)
共記錄 ＝ 文本_取出中間文本 (返回文本, #引號 ＋ “count” ＋ #引號 ＋ “: ” ＋ #引號, #引號)
查詢按鈕.標題 ＝ “停止查詢[1/” ＋ 共記錄 ＋ “]”
頁數 ＝ 0
超級列表框.全部刪除 ()
線程_初始化COM庫 ()
.判斷循環首 (共記錄 ≠ “”)
  頁數 ＝ 頁數 ＋ 1
  返回文本 ＝ 網頁_訪問S (“http://my.pay.qq.com/cgi-bin/personal/account_tradeinfo.cgi?coin_type=0&start_date=” ＋ 起始編輯框.內容 ＋ “&end_date=” ＋ 截止編輯框.內容 ＋ “&page_no=” ＋ 到文本 (頁數) ＋ “&channel=qdqb&per=10&extcode=&t=” ＋ 時間_取隨機時間戳 (), , , Cookie)
  返回文本 ＝ 編碼_usc2到ansi (返回文本)
  調試輸出 (返回文本)
  正則.創建 (#常量1, 返回文本)
  .計次循環首 (正則.取匹配數量 (), i)
    M ＝ 超級列表框.插入表項 (, , , , , )
    超級列表框.置標題 (M, 0, 正則.取子匹配文本 (i, 6))
    超級列表框.置標題 (M, 1, 子程序_處理類型 (正則.取子匹配文本 (i, 1)))
    超級列表框.置標題 (M, 2, 子程序_處理收入 (正則.取子匹配文本 (i, 5)))
    超級列表框.置標題 (M, 3, 子程序_處理收入 (正則.取子匹配文本 (i, 4)))
    超級列表框.置標題 (M, 4, 正則.取子匹配文本 (i, 2))
    超級列表框.置標題 (M, 5, 正則.取子匹配文本 (i, 3))
    查詢按鈕.標題 ＝ “停止查詢[” ＋ 到文本 (超級列表框.取表項數 ()) ＋ “/” ＋ 共記錄 ＋ “]”
  .計次循環尾 ()
  .如果真 (尋找文本 (返回文本, #常量2, , 假) ≠ -1)
    跳出循環 ()
  .如果真結束
  .如果真 (查詢按鈕.標題 ＝ “開始查詢”)
    跳出循環 ()
  .如果真結束
  程序_延時 (50)
.判斷循環尾 ()
查詢按鈕.標題 ＝ “開始查詢”
線程_取消COM庫 ()
查詢按鈕.禁止 ＝ 假
信息框 (“日期:” ＋ 起始編輯框.內容 ＋ “ - ” ＋ 截止編輯框.內容 ＋ #換行符 ＋ #換行符 ＋ “共消費了：” ＋ 子程序_計算消費 () ＋ “ Q幣”, 0, “消費結果：”, _啟動窗口)
.子程序 子程序_計算消費, 文本型
.局部變量 i, 整數型
.局部變量 消費, 文本型
.局部變量 Q幣, 文本型
.局部變量 總數, 文本型
.計次循環首 (超級列表框.取表項數 (), i)
  消費 ＝ 超級列表框.取標題 (i － 1, 3)
  Q幣 ＝ 超級列表框.取標題 (i － 1, 1)
  .如果真 (Q幣 ＝ “Q幣” 或 Q幣 ＝ “Q點”)
    .如果真 (Q幣 ＝ “Q點”)
      消費 ＝ 到文本 (到數值 (消費) ÷ 10)
    .如果真結束
    總數 ＝ 到文本 (到數值 (總數) ＋ 到數值 (消費))
  .如果真結束
.計次循環尾 ()
返回 (總數)
.子程序 子程序_處理類型, 文本型
.參數 accttype, 文本型
.如果真 (accttype ＝ “1”)
  返回 (“Q幣”)
.如果真結束
.如果真 (accttype ＝ “3”)
  返回 (“Q點”)
.如果真結束
返回 (accttype)
.子程序 子程序_處理收入, 文本型
.參數 收入, 文本型
.如果真 (收入 ＝ “”)
  返回 (“—”)
.如果真結束
返回 (收入)
.子程序 _導出按鈕_被單擊
.局部變量 i, 整數型
.局部變量 導出的內容, 文本型
.計次循環首 (超級列表框.取表項數 (), i)
  導出的內容 ＝ 導出的內容 ＋ 超級列表框.取標題 (i － 1, 0) ＋ “--” ＋ 超級列表框.取標題 (i － 1, 1) ＋ “--” ＋ 超級列表框.取標題 (i － 1, 2) ＋ “--” ＋ 超級列表框.取標題 (i － 1, 3) ＋ “--” ＋ 超級列表框.取標題 (i － 1, 5) ＋ “--” ＋ 超級列表框.取標題 (i － 1, 6) ＋ #換行符
  處理事件 ()
.計次循環尾 ()
.如果 (寫到文件 (取運行目錄 () ＋ “\[” ＋ QQ號碼 ＋ “]Q幣消費查詢.txt”, 到字節集 (導出的內容)))
  信息框 (“導出成功”, 0, , )
.否則
  信息框 (“導出失敗”, 0, , )
.如果結束