使用易語言怎么批量刪除QQ空間留言

今天就跟大家聊聊有關使用易語言怎么批量刪除QQ空間留言，可能很多人都不太了解，為了讓大家更加了解，小編給大家總結了以下內容，希望大家根據這篇文章可以有所收獲。

全局變量表

.版本 2
.全局變量 Uin_全, 文本型
.全局變量 Cookie_全, 文本型

QQ快捷啟動的代碼

.版本 2
.支持庫 HtmlView
.支持庫 iext
.程序集 窗口程序集_快速
.子程序 _超文本瀏覽框1_跳轉完畢
.局部變量 返回文本, 文本型
.局部變量 文本分割, 文本型, , "0"
.局部變量 二次分割, 文本型, , "0"
.局部變量 i, 整數型
.局部變量 s, 整數型
.局部變量 Cookie, 文本型
.局部變量 Uin, 文本型
.局部變量 Skey, 文本型
.局部變量 obj_doc, 對象
obj_doc ＝ 超文本瀏覽框1.取文檔對象 ()
Cookie_全 ＝ obj_doc.讀文本屬性 (“cookie”, )
Uin_全 ＝ 文本_取出中間文本 (Cookie_全, “p_uin=o”, “;”)
.判斷循環首 (尋找文本 (Uin_全, “0”, , 假) ＝ 1)
  Uin_全 ＝ 取文本右邊 (Uin_全, 取文本長度 (Uin_全) － 1)
.判斷循環尾 ()
.如果真 (Cookie_全 ≠ “” 且 Uin_全 ≠ “”)
  _啟動窗口.標簽_QQ號碼.標題 ＝ “QQ號碼：” ＋ Uin_全
  _啟動窗口.標簽_狀態.標題 ＝ “狀 態：登錄成功”
  _啟動窗口.圖片框1.圖片 ＝ 獲取QQ頭像 (Uin_全)
  _啟動窗口.按鈕_快速登錄.標題 ＝ “登錄成功”
  _啟動窗口.超級列表框1.全部刪除 ()
  返回文本 ＝ 獲取留言列表 (Uin_全, Cookie_全)
  文本分割 ＝ 分割文本 (返回文本, #換行符, )
  .計次循環首 (取數組成員數 (文本分割), i)
    二次分割 ＝ 分割文本 (文本分割 [i], “|”, )
    s ＝ _啟動窗口.超級列表框1.插入表項 (, , , , , )
    _啟動窗口.超級列表框1.置標題 (s, 0, 到文本 (i))
    _啟動窗口.超級列表框1.置標題 (s, 1, 二次分割 [1])
    _啟動窗口.超級列表框1.置標題 (s, 2, 二次分割 [2])
    _啟動窗口.超級列表框1.置標題 (s, 3, 二次分割 [3])
    _啟動窗口.超級列表框1.置標題 (s, 4, 二次分割 [4])
    _啟動窗口.超級列表框1.置標題 (s, 5, 二次分割 [5])
    _啟動窗口.超級列表框1.置標題 (s, 6, “null”)
  .計次循環尾 ()
  窗口_快速.銷毀 ()
.如果真結束
.子程序 _窗口_快速_將被銷毀
窗口_快速.銷毀 ()

獲取和計算的代碼

.版本 2
.程序集 程序集1
.子程序 獲取QQ頭像, 字節集, 公開
.參數 QQ號碼, 文本型
.局部變量 提交地址, 文本型
.局部變量 返回字節, 字節集
提交地址 ＝ “http://q2.qlogo.cn/headimg_dl?bs=qq&dst_uin=” ＋ QQ號碼 ＋ “&src_uin=” ＋ QQ號碼 ＋ “&fid=” ＋ QQ號碼 ＋ “&spec=100&url_enc=0&referer=bu_interface&term_type=PC”
返回字節 ＝ 網頁_訪問 (提交地址)
返回 (返回字節)
.子程序 獲取留言列表, 文本型
.參數 QQ號碼, 文本型
.參數 Cookie, 文本型
.局部變量 提交地址, 文本型
.局部變量 返回文本, 文本型
.局部變量 json, 類_json
.局部變量 qzonetoken, 文本型
.局部變量 p_skey, 文本型
.局部變量 g_tk, 文本型
.局部變量 i, 整數型
.局部變量 uin, 文本型
.局部變量 nickname, 文本型
.局部變量 content, 文本型
.局部變量 id, 文本型
.局部變量 time, 文本型
.局部變量 結果, 文本型
p_skey ＝ 文本_取出中間文本 (Cookie, “p_skey=”, “;”)
g_tk ＝ 計算G_tk (p_skey)
qzonetoken ＝ 計算QzoneToken (QQ號碼)
提交地址 ＝ “https://user.qzone.qq.com/proxy/domain/m.qzone.qq.com/cgi-bin/new/get_msgb?uin=” ＋ QQ號碼 ＋ “&hostUin=” ＋ QQ號碼 ＋ “&start=0&s=” ＋ 時間_取隨機時間戳 () ＋ “&format=jsonp&num=20&inCharset=utf-8&outCharset=utf-8&g_tk=” ＋ g_tk ＋ “&qzonetoken=” ＋ qzonetoken ＋ “&g_tk=” ＋ g_tk
返回文本 ＝ 編碼_Utf8到Ansi (網頁_訪問 (提交地址, , , Cookie))
返回文本 ＝ 子文本替換 (返回文本, “_Callback(”, “”, , , 真)
返回文本 ＝ 子文本替換 (返回文本, “);”, “”, , , 真)
' 調試輸出 (返回文本)
json.解析 (返回文本)
_啟動窗口.標簽_留言數.標題 ＝ “留言數：” ＋ json.取通用屬性 (“data.total”)
.計次循環首 (json.成員數 (“data.commentList”), i)
  uin ＝ json.取通用屬性 (“data.commentList[” ＋ 到文本 (i － 1) ＋ “].uin”)
  nickname ＝ json.取通用屬性 (“data.commentList[” ＋ 到文本 (i － 1) ＋ “].nickname”)
  content ＝ json.取通用屬性 (“data.commentList[” ＋ 到文本 (i － 1) ＋ “].ubbContent”)
  id ＝ json.取通用屬性 (“data.commentList[” ＋ 到文本 (i － 1) ＋ “].id”)
  time ＝ json.取通用屬性 (“data.commentList[” ＋ 到文本 (i － 1) ＋ “].pubtime”)
  結果 ＝ 結果 ＋ uin ＋ “|” ＋ nickname ＋ “|” ＋ content ＋ “|” ＋ id ＋ “|” ＋ time ＋ #換行符
  ' 調試輸出 (uin, nickname, content, id, time)
.計次循環尾 ()
返回 (結果)
.子程序 PC刪除留言, 文本型, 公開
.參數 QQ號碼, 文本型
.參數 對方QQ, 文本型
.參數 留言ID, 文本型
.參數 Cookie, 文本型
.局部變量 提交地址, 文本型
.局部變量 提交數據, 文本型
.局部變量 返回文本, 文本型
.局部變量 qzonetoken, 文本型
.局部變量 p_skey, 文本型
.局部變量 g_tk, 文本型
.局部變量 json, 類_json
.局部變量 code, 文本型
p_skey ＝ 文本_取出中間文本 (Cookie, “p_skey=”, “;”)
g_tk ＝ 計算G_tk (p_skey)
qzonetoken ＝ 計算QzoneToken (QQ號碼)
提交地址 ＝ “https://h6.qzone.qq.com/proxy/domain/m.qzone.qq.com/cgi-bin/new/del_msgb?qzonetoken=” ＋ qzonetoken ＋ “&g_tk=” ＋ g_tk
提交數據 ＝ “hostUin=” ＋ QQ號碼 ＋ “&idList=” ＋ 留言ID ＋ “&uinList=” ＋ 對方QQ ＋ “&format=fs&iNotice=1&inCharset=utf-8&outCharset=utf-8&ref=qzone&json=1&g_tk=” ＋ g_tk ＋ “&qzreferrer=https%3A%2F%2Fqzs.qq.com%2Fqzone%2Fmsgboard%2Fmsgbcanvas.html%23page%3D1”
返回文本 ＝ 編碼_Utf8到Ansi (網頁_訪問 (提交地址, 1, 提交數據, Cookie))
返回 (返回文本)
.子程序 計算G_tk, 文本型, 公開
.參數 skey, 文本型
.局部變量 hash, 整數型
.局部變量 i, 整數型
hash ＝ 5381
.計次循環首 (取文本長度 (skey), i)
  hash ＝ hash ＋ 左移 (hash, 5) ＋ 取代碼 (skey, i)
.計次循環尾 ()
hash ＝ 位與 (hash, 2147483647)
返回 (到文本 (hash))
.子程序 計算QzoneToken, 文本型
.參數 Uin, 文本型
.局部變量 Url, 文本型
.局部變量 Ret, 文本型
Url ＝ “https://user.qzone.qq.com/” ＋ Uin
Ret ＝ 編碼_Utf8到Ansi (網頁_訪問 (Url))
返回 (文本_取出中間文本 (Ret, “window.g_qzonetoken = (function(){ try{return ” ＋ #引號, #引號 ＋ “;}”))

QQ空間留言批量刪除的代碼

此功能需要加載精易模塊5.6

.版本 2
.支持庫 EThread
.支持庫 iext
.支持庫 spec
.程序集 窗口程序集_啟動窗口
.程序集變量 線程ID, 整數型
.子程序 __啟動窗口_創建完畢
圖片框1.圖片 ＝ 獲取QQ頭像 (“10000”)
.子程序 _按鈕_快速登錄_被單擊
載入 (窗口_快速, , 假)
.子程序 _按鈕_批量刪除_被單擊
.如果 (按鈕_批量刪除.標題 ＝ “批量刪除”)
  按鈕_批量刪除.標題 ＝ “停止刪除”
  啟動線程 (&獲取留言, , 線程ID)
.否則
  按鈕_批量刪除.標題 ＝ “批量刪除”
.如果結束
.子程序 獲取留言
.局部變量 返回文本, 文本型
.局部變量 文本分割, 文本型, , "0"
.局部變量 二次分割, 文本型, , "0"
.局部變量 i, 整數型
.局部變量 s, 整數型
超級列表框1.全部刪除 ()
返回文本 ＝ 獲取留言列表 (Uin_全, Cookie_全)
文本分割 ＝ 分割文本 (返回文本, #換行符, )
.計次循環首 (取數組成員數 (文本分割), i)
  二次分割 ＝ 分割文本 (文本分割 [i], “|”, )
  s ＝ 超級列表框1.插入表項 (, , , , , )
  超級列表框1.置標題 (s, 0, 到文本 (i))
  超級列表框1.置標題 (s, 1, 二次分割 [1])
  超級列表框1.置標題 (s, 2, 二次分割 [2])
  超級列表框1.置標題 (s, 3, 二次分割 [3])
  超級列表框1.置標題 (s, 4, 二次分割 [4])
  超級列表框1.置標題 (s, 5, 二次分割 [5])
  超級列表框1.置標題 (s, 6, “null”)
.計次循環尾 ()
啟動線程 (&刪除留言, , )
.子程序 刪除留言
.局部變量 對方QQ, 文本型
.局部變量 留言ID, 文本型
.局部變量 i, 整數型
.局部變量 返回文本, 文本型
.如果真 (超級列表框1.取表項數 () ＝ 0)
  信息框 (“沒有要刪除的留言”, #信息圖標, “溫馨提示”)
  按鈕_批量刪除.標題 ＝ “批量刪除”
  返回 ()
.如果真結束
.計次循環首 (超級列表框1.取表項數 (), i)
  對方QQ ＝ 超級列表框1.取標題 (i － 1, 1)
  留言ID ＝ 超級列表框1.取標題 (i － 1, 4)
  ' 調試輸出 (對方QQ, 留言ID)
  返回文本 ＝ PC刪除留言 (Uin_全, 對方QQ, 留言ID, Cookie_全)
  調試輸出 (返回文本)
  .如果 (尋找文本 (返回文本, #引號 ＋ “code” ＋ #引號 ＋ “:0”, , 假) ≠ -1)
    超級列表框1.置標題 (i － 1, 6, “√”)
  .否則
    超級列表框1.置標題 (i － 1, 6, “×”)
  .如果結束
  .如果真 (i ≥ 超級列表框1.取表項數 ())
    啟動線程 (&獲取留言, , )
    跳出循環 ()
  .如果真結束
  .如果真 (按鈕_批量刪除.標題 ＝ “批量刪除”)
    跳出循環 ()
  .如果真結束
  延遲 (到整數 (編輯框1.內容))
.計次循環尾 ()
.子程序 _按鈕_注銷登錄_被單擊
網頁_清除Cookie (“qq.com”)
網頁_清除Cookie (“gdt.qq.com”)
網頁_清除Cookie (“ptlogin2.qq.com”)
網頁_清除Cookie (“xui.ptlogin2.qq.com”)
網頁_清除Cookie (“qzone.qq.com”)
網頁_清除Cookie (“user.qzone.qq.com”)
網頁_清除Cookie (“qzs.qq.com”)
網頁_清除Cookie (“qzone.qq.com”)
按鈕_快速登錄.標題 ＝ “快速登錄”
標簽_QQ號碼.標題 ＝ “QQ號碼：未登錄”
標簽_狀態.標題 ＝ “狀態：未登錄”
標簽_留言數.標題 ＝ “留言數：未登錄”
圖片框1.圖片 ＝ 獲取QQ頭像 (“10000”)
超級列表框1.全部刪除 ()
信息框 (“注銷登錄成功”, 0, )

運行結果：

看完上述內容，你們對使用易語言怎么批量刪除QQ空間留言有進一步的了解嗎？如果還想了解更多知識或者相關內容，請關注億速云行業資訊頻道，感謝大家的支持。