易語言中Ex_DirectUI如何自繪掃雷游戲

小編給大家分享一下易語言中Ex_DirectUI如何自繪掃雷游戲，相信大部分人都還不怎么了解，因此分享這篇文章給大家參考一下，希望大家閱讀完這篇文章后大有收獲，下面讓我們一起去了解一下吧！

MineMartix

.版本 2
.支持庫 spec
.程序集 MineMartix, Ex_控件基類, , ExDUI擴展組件_掃雷按鈕
.程序集變量 m_顏色, 整數型
.程序集變量 m_透明度, 整數型
.程序集變量 m_Rect, RectF
.程序集變量 m_hIcon, 整數型, , , 圖像句柄
.程序集變量 m_單擊回調指針, 整數型
.程序集變量 m_Mine, 邏輯型
.程序集變量 m_Pos, PointF
.程序集變量 m_Num, 整數型, , , 周圍雷數量
.程序集變量 m_pFont, 整數型, , , 字體指針
.程序集變量 m_GPs, Gdip_文本格式
.程序集變量 m_ClickdColor, 整數型, , , 點擊后顏色
.程序集變量 m_CurrentColor, 整數型, , , 當前顏色
.子程序 _初始化, , , 當基于本類的對象被創建后，此方法會被自動調用
.子程序 _銷毀, , , 當基于本類的對象被銷毀前，此方法會被自動調用
.子程序 Obj, 整數型
.參數 hWnd, 整數型
.參數 msg, 整數型
.參數 wParam, 整數型
.參數 lParam, 整數型
.判斷開始 (msg ＝ #事件_初始化)
 m_pFont ＝ 字體_創建 (“微軟雅黑”, 12)
 m_GPs.創建 (#文本格式標志_不換行)
 m_ClickdColor ＝ RGB2ARGB (#黑色, 80)
 重畫 ()
 調試輸出 (hWnd, msg)
.判斷 (msg ＝ #事件_銷毀)
 圖像_銷毀 (m_hIcon)
.判斷 (msg ＝ #事件_繪畫)
 Paint (hWnd, 1)
.判斷 (msg ＝ #事件_動畫開始)
 動畫類型 (#動畫類型_默認)
.判斷 (msg ＝ #事件_動畫結束)
 動畫幀數 (0)
.判斷 (msg ＝ #事件_進入組件)
 動畫幀數 (16, 10)
 Paint (hWnd, 2)
.判斷 (msg ＝ #事件_離開組件)
 動畫幀數 (16, 10)
 Paint (hWnd, 1)
.判斷 (msg ＝ #事件_左鍵按下)
 動畫幀數 (16, 10)
 Paint (hWnd, 3)
.判斷 (msg ＝ #事件_左鍵放開)
 動畫幀數 (16, 10)
 Paint (hWnd, 2)
 .如果真 (m_CurrentColor ≠ #黑色)
  .如果真 (m_單擊回調指針 ≠ 0)
   調用子程序_ (m_單擊回調指針, m_Pos.x, m_Pos.y)
  .如果真結束
 .如果真結束
.默認
.判斷結束
返回 (-1)
.子程序 Paint
.參數 hObj, 整數型
.參數 Status, 整數型, , 1.正常 2.點燃 2.按下
.局部變量 m_ps, Exs_PaintStruct
.局部變量 color, 整數型
Ex_BeginPaint (hObj, m_ps, , 真)
.如果真 (Status ＝ 1)
 圖形_填充_矩形 (m_ps.mGraphics, m_ps.Rcf, RGB2ARGB (m_CurrentColor, m_透明度)) ' 畫正常狀態
.如果真結束
.如果真 (Status ＝ 2)
 圖形_填充_矩形 (m_ps.mGraphics, m_ps.Rcf, RGB2ARGB (m_CurrentColor, 180)) ' 畫點燃狀態
.如果真結束
.如果真 (Status ＝ 3)
 圖形_填充_矩形 (m_ps.mGraphics, m_ps.Rcf, RGB2ARGB (m_CurrentColor, m_透明度 ＋ 40)) ' 畫按下狀態
.如果真結束
.如果真 (m_hIcon ≠ 0)
 圖形_繪圖 (m_ps.mGraphics, m_hIcon, m_ps.Rcf, 真) ' 畫雷圖片
.如果真結束
.如果真 (m_Num ≠ 0)
 .如果真 (m_Num ＝ 1)
  color ＝ RGB2ARGB (#藍色)
 .如果真結束
 .如果真 (m_Num ＝ 2)
  color ＝ RGB2ARGB (#綠色)
 .如果真結束
 .如果真 (m_Num ＝ 3)
  color ＝ RGB2ARGB (#紅色)
 .如果真結束
 .如果真 (m_Num ＝ 4)
  color ＝ RGB2ARGB (#紫色)
 .如果真結束
 .如果真 (m_Num ＝ 5)
  color ＝ RGB2ARGB (#紅褐)
 .如果真結束
 .如果真 (m_Num ＝ 6)
  color ＝ RGB2ARGB (#天藍)
 .如果真結束
 .如果真 (m_Num ＝ 7)
  color ＝ RGB2ARGB (#白色)
 .如果真結束
 .如果真 (m_Num ＝ 8)
  color ＝ RGB2ARGB (#深灰)
 .如果真結束
 圖形_畫文本 (m_ps.mGraphics, MakeRCF (m_ps.Rcf.left ＋ 3, m_ps.Rcf.top, m_ps.Rcf.Width, m_ps.Rcf.Height), A2W (到文本 (m_Num)), m_pFont, color, m_GPs.取指針 (), #文本效果_描邊, RGB2ARGB (#白色, 120)) ' 畫標題
.如果真結束
圖形_描邊_矩形 (m_ps.mGraphics, m_ps.Rcf, #邊框_單線式, RGB2ARGB (#白色), 1) ' 畫邊框
Ex_EndPaint (hObj, m_ps)
.子程序 Create, 整數型, 公開
.參數 窗口句柄, 整數型
.參數 左邊, 整數型
.參數 頂邊, 整數型
.參數 寬度, 整數型
.參數 高度, 整數型
.參數 顏色, 整數型, , rgb
.參數 透明度, 整數型
m_顏色 ＝ 顏色
m_CurrentColor ＝ m_顏色
m_透明度 ＝ 透明度
m_Rect.left ＝ 左邊
m_Rect.top ＝ 頂邊
m_Rect.Width ＝ 寬度
m_Rect.Height ＝ 高度
返回 (初始化 (窗口句柄, m_Rect, 1020150, 真, , #鼠標指針_手型))
.子程序 SetIcon, , 公開
.參數 Icon, 字節集
.如果真 (Icon ＝ { 0 })
 .如果真 (m_hIcon ≠ 0)
  圖像_銷毀 (m_hIcon)
  m_hIcon ＝ 0
 .如果真結束
 重畫 ()
.如果真結束
m_hIcon ＝ 圖像_創建自字節集 (Icon)
重畫 ()
.子程序 SetClickEvents, , 公開
.參數 pcbk, 整數型
m_單擊回調指針 ＝ pcbk
.子程序 SetXY, , 公開, 設置坐標
.參數 x, 整數型
.參數 y, 整數型
m_Pos.x ＝ x
m_Pos.y ＝ y
.子程序 SetMine, , 公開, 設置為雷
m_Mine ＝ 真
.子程序 CleanMine, , 公開, 清除雷
m_Mine ＝ 假
.子程序 CheckMine, 邏輯型, 公開, 檢測是否為雷
返回 (m_Mine)
.子程序 SetMineNum, , 公開, 設置周圍雷數量
.參數 Num, 整數型
m_Num ＝ Num
重畫 ()
.子程序 SetStatus, , 公開
.參數 Status, 整數型, , 0.未點擊狀態 1.點擊后狀態
.如果真 (Status ＝ 0)
 m_CurrentColor ＝ m_顏色
.如果真結束
.如果真 (Status ＝ 1)
 m_CurrentColor ＝ #黑色
.如果真結束
重畫 ()
.子程序 GetStatus, 整數型, 公開
.如果真 (m_CurrentColor ＝ m_顏色)
 返回 (0)
.如果真結束
.如果真 (m_CurrentColor ＝ #黑色)
 返回 (1)
.如果真結束
返回 (0)

自繪掃雷游戲

此功能需要加載Ex_DirectUI 2.0模塊

.版本 2
.支持庫 eAPI
.程序集 窗口程序集1
.程序集變量 Ex, Ex_DirectUI
.程序集變量 Martix, MineMartix, , "10,10"
.程序集變量 Mine, PointF, , "0"
.程序集變量 ScorePos, PointF, , "0"
.程序集變量 Btn, 按鈕_Ex
.程序集變量 TimeBtn, 超級按鈕_Ex
.程序集變量 ScoreBtn, 超級按鈕_Ex
.程序集變量 restartBtn, 超級按鈕_Ex
.程序集變量 Frame, 分組框_Ex
.程序集變量 Time, 整數型
.程序集變量 Score, 整數型
.子程序 __啟動窗口_創建完畢
.局部變量 i, 整數型
.局部變量 j, 整數型
Ex.掛接皮膚 (取窗口句柄 (), , #銀白, 1 ＋ 2 ＋ 4, 150, , 0, , , , , 假)
Frame.創建 (取窗口句柄 (), 16, 66, 180, 180)
.計次循環首 (10, i)
 .計次循環首 (10, j)
  Martix [i] [j].Create (取窗口句柄 (), j × 16 ＋ 10, i × 16 ＋ 60, 16 ＋ 1, 16 ＋ 1, #天藍, 100) ' 掃雷按鈕矩陣
  Martix [i] [j].SetXY (i, j)
  Martix [i] [j].SetClickEvents (到整數 (&Martix_Click)) ' 掛接單擊事件
 .計次循環尾 ()
.計次循環尾 ()
TimeBtn.創建 (取窗口句柄 (), 16, 30, 76, 30, “Time:001”)
restartBtn.創建 (取窗口句柄 (), 92, 30, 30, 30, “重置”)
restartBtn.掛接事件 (10244, &Init)
ScoreBtn.創建 (取窗口句柄 (), 122, 30, 73, 30, “Score:000”)
Btn.掛接事件 (10244, &Init)
Init ()
Ex.置進入特效 (7)
Ex.置退出特效 (2)
.子程序 RandPoint, PointF, , 生成隨機不重復坐標
.參數 最大值, 整數型
.參數 數量, 整數型
.局部變量 nPoint, PointF, 靜態, "0"
.局部變量 i, 整數型
.計次循環首 (數量, i)
 nPoint.x ＝ 取隨機數 (1, 最大值)
 nPoint.y ＝ 取隨機數 (1, 最大值)
.計次循環尾 ()
.子程序 Init
.局部變量 x, 整數型
.局部變量 y, 整數型
.局部變量 i, 整數型
.局部變量 Point, PointF
時鐘1.時鐘周期 ＝ 0
Score ＝ 0
Time ＝ 0
ScoreBtn.標題 (“Score:000”)
TimeBtn.標題 (“Time:000”)
置隨機數種子 ()
.計次循環首 (取數組成員數 (Mine), i) ' 清除雷
 Martix [Mine [i].x] [Mine [i].y].SetIcon ({ 0 })
 Martix [Mine [i].x] [Mine [i].y].CleanMine ()
 Martix [Mine [i].x] [Mine [i].y].重畫 ()
.計次循環尾 ()
.計次循環首 (取數組成員數 (ScorePos), i) ' 清除已經點過的方格
 Martix [ScorePos [i].x] [ScorePos [i].y].SetStatus (0)
 Martix [ScorePos [i].x] [ScorePos [i].y].SetMineNum (0)
 Martix [ScorePos [i].x] [ScorePos [i].y].重畫 ()
.計次循環尾 ()
清除數組 (Mine)
清除數組 (ScorePos)
.計次循環首 (10, i) ' 隨機埋雷
 x ＝ 取隨機數 (1, 10)
 y ＝ 取隨機數 (1, 10)
 Martix [x] [y].SetMine ()
 Point.x ＝ x
 Point.y ＝ y
 加入成員 (Mine, Point)
.計次循環尾 ()
.子程序 Martix_Click
.參數 x, 整數型
.參數 y, 整數型
.局部變量 i, 整數型
.如果真 (時鐘1.時鐘周期 ＝ 0)
 時鐘1.時鐘周期 ＝ 1000
.如果真結束
.如果 (ClickMine (x, y) ＝ 真)
 增加分數 (x, y)
 .計次循環首 (10, i)
  Martix [Mine [i].x] [Mine [i].y].SetIcon (#MinePic)
 .計次循環尾 ()
 時鐘1.時鐘周期 ＝ 0
 信息框_Ex (取窗口句柄 (), “您輸了! 分數:” ＋ 到文本 (取數組成員數 (ScorePos)), , , , , , , , , , 真, , #銀白, 120, 0, , , 假, , 7, 2)
 Init ()
.否則
 .如果 (Score ＜ 90)
  自動區域 (x, y)
 .否則
  時鐘1.時鐘周期 ＝ 0
  信息框_Ex (取窗口句柄 (), “恭喜通關! 時間:” ＋ 到文本 (Time), , , , , , , , , , 真, , #銀白, 120, 0, , , 假, , 7, 2)
  Init ()
 .如果結束
.如果結束
.子程序 ClickMine, 邏輯型, , 點擊方格，點到雷返回真
.參數 x, 整數型
.參數 y, 整數型
.如果真 (Martix [x] [y].GetStatus () ＝ 0)
 增加分數 (x, y)
 Martix [x] [y].SetStatus (1)
 .如果真 (Martix [x] [y].CheckMine () ＝ 真)
  返回 (真)
 .如果真結束
 返回 (假)
.如果真結束
返回 (假)
.子程序 增加分數
.參數 x, 整數型
.參數 y, 整數型
.局部變量 Point, PointF
Point.x ＝ x
Point.y ＝ y
加入成員 (ScorePos, Point)
Martix [x] [y].SetMineNum (計算雷數 (x, y))
Score ＝ Score ＋ 1
ScoreBtn.標題 (“Score:” ＋ 格式化文本 (“%.3d”, Score))
.子程序 計算雷數, 整數型, , 計算九宮格內的雷數
.參數 x, 整數型
.參數 y, 整數型
.局部變量 Num, 整數型
.如果真 (x ≠ 1)
 .如果真 (Martix [x － 1] [y].CheckMine () ＝ 真) ' 左邊
  Num ＝ Num ＋ 1
 .如果真結束
.如果真結束
.如果真 (x ＜ 10)
 .如果真 (Martix [x ＋ 1] [y].CheckMine () ＝ 真) ' 右邊
  Num ＝ Num ＋ 1
 .如果真結束
.如果真結束
.如果真 (y ≠ 1)
 .如果真 (Martix [x] [y － 1].CheckMine () ＝ 真) ' 上邊
  Num ＝ Num ＋ 1
 .如果真結束
.如果真結束
.如果真 (y ＜ 10)
 .如果真 (Martix [x] [y ＋ 1].CheckMine () ＝ 真) ' 下邊
  Num ＝ Num ＋ 1
 .如果真結束
.如果真結束
.如果真 (x ≠ 1 且 y ≠ 1)
 .如果真 (Martix [x － 1] [y － 1].CheckMine () ＝ 真) ' 左上角
  Num ＝ Num ＋ 1
 .如果真結束
.如果真結束
.如果真 (x ＜ 10 且 y ＜ 10)
 .如果真 (Martix [x ＋ 1] [y ＋ 1].CheckMine () ＝ 真) ' 右下角
  Num ＝ Num ＋ 1
 .如果真結束
.如果真結束
.如果真 (x ≠ 1 且 y ＜ 10)
 .如果真 (Martix [x － 1] [y ＋ 1].CheckMine () ＝ 真) ' 左下角
  Num ＝ Num ＋ 1
 .如果真結束
.如果真結束
.如果真 (x ＜ 10 且 y ≠ 1)
 .如果真 (Martix [x ＋ 1] [y － 1].CheckMine () ＝ 真) ' 右上角
  Num ＝ Num ＋ 1
 .如果真結束
.如果真結束
返回 (Num)
.子程序 自動區域
.參數 x, 整數型
.參數 y, 整數型
.如果真 (計算雷數 (x, y) ＝ 0)
 .如果真 (x ≠ 1)
  ClickMine (x － 1, y)
 .如果真結束
 .如果真 (x ＜ 10)
  ClickMine (x ＋ 1, y)
 .如果真結束
 .如果真 (y ≠ 1)
  ClickMine (x, y － 1)
 .如果真結束
 .如果真 (y ＜ 10)
  ClickMine (x, y ＋ 1)
 .如果真結束
 .如果真 (x ≠ 1 且 y ≠ 1)
  ClickMine (x － 1, y － 1)
 .如果真結束
 .如果真 (x ＜ 10 且 y ＜ 10)
  ClickMine (x ＋ 1, y ＋ 1)
 .如果真結束
 .如果真 (x ≠ 1 且 y ＜ 10)
  ClickMine (x － 1, y ＋ 1)
 .如果真結束
 .如果真 (x ＜ 10 且 y ≠ 1)
  ClickMine (x ＋ 1, y － 1)
 .如果真結束
 ClickMine (x, y)
.如果真結束
.子程序 _時鐘1_周期事件
Time ＝ Time ＋ 1
TimeBtn.標題 (格式化文本 (“Time:%.3d”, Time))

運行結果：

以上是“易語言中Ex_DirectUI如何自繪掃雷游戲”這篇文章的所有內容，感謝各位的閱讀！相信大家都有了一定的了解，希望分享的內容對大家有所幫助，如果還想學習更多知識，歡迎關注億速云行業資訊頻道！