易語言如何實現電腦屏幕鎖定工具

小編給大家分享一下易語言如何實現電腦屏幕鎖定工具，相信大部分人都還不怎么了解，因此分享這篇文章給大家參考一下，希望大家閱讀完這篇文章后大有收獲，下面讓我們一起去了解一下吧！

DLLL命令表

.版本 2
.DLL命令 安裝鉤子, 整數型, , "SetWindowsHookExA"
  .參數 ihook, 整數型
  .參數 lpfunc, 子程序指針
  .參數 hin, 整數型
  .參數 threadid, 整數型
.DLL命令 卸載鉤子, 整數型, , "UnhookWindowsHookEx"
  .參數 hHook, 整數型
.DLL命令 下一個鉤子, 整數型, , "CallNextHookEx"
  .參數 hHook, 整數型
  .參數 icode, 整數型
  .參數 wParam, 整數型
  .參數 lParam, 整數型
.DLL命令 CopyMemory, , , "RtlMoveMemory"
  .參數 Destination, 按鍵信息, 傳址
  .參數 Source, 整數型
  .參數 cbCopy, 整數型
.DLL命令 GetModuleHandleA, 整數型, , "GetModuleHandleA"
  .參數 lpModuleName, 整數型
.DLL命令 SetWindowPos, 整數型, "user32"
  .參數 HWnd, 整數型
  .參數 hWndInsertAfter, 整數型
  .參數 X, 整數型
  .參數 Y, 整數型
  .參數 cx, 整數型
  .參數 cy, 整數型
  .參數 wFlags, 整數型

自定義數據類型表

.版本 2
.數據類型 按鍵信息
  .成員 虛擬碼, 整數型
  .成員 掃描碼, 整數型
  .成員 標記, 整數型
  .成員 時間, 整數型
  .成員 額外信息, 整數型

鎖屏框

.版本 2
.支持庫 eAPI
.程序集 窗口程序集1
.程序集變量 鉤子句柄, 整數型
.子程序 _編輯框_解鎖密碼框_內容被改變
標簽2.標題 ＝ “屏幕鎖定中。。。”
標簽2.文本顏色 ＝ #銀白
.子程序 _窗口1_鎖屏框_創建完畢
設置窗口透明度 (取窗口句柄 (), 250)
窗口1_鎖屏框.左邊 ＝ 0
窗口1_鎖屏框.頂邊 ＝ 0
窗口1_鎖屏框.寬度 ＝ 取屏幕寬度 ()
窗口1_鎖屏框.高度 ＝ 取屏幕高度 ()
圖片框1.左邊 ＝ 取屏幕寬度 () ÷ 2 － 圖片框1.寬度 ÷ 2
圖片框1.頂邊 ＝ 取屏幕高度 () ÷ 2 － 圖片框1.高度 ÷ 2
注冊屏蔽 ()
.子程序 窗口總在最前
.參數 參_窗口句柄, 整數型
SetWindowPos (參_窗口句柄, -1, 0, 0, 0, 0, 位或 (2, 1))
.子程序 _圖形按鈕1_被單擊
_按鈕1_被單擊 ()
.子程序 _按鈕1_被單擊
.如果 (編輯框_解鎖密碼框.內容 ＝ “”)
  標簽2.標題 ＝ “未輸入密碼，請重新輸入！”
  標簽2.文本顏色 ＝ #紅色
.否則
  .如果 (編輯框_解鎖密碼框.內容 ＝ “123”)
    解除屏蔽 ()
    結束 ()
  .否則
    .如果 (編輯框_解鎖密碼框.內容 ≠ _啟動窗口.編輯框_重復密碼框.內容)
      標簽2.標題 ＝ “密碼不正確，請重新輸入！”
      標簽2.文本顏色 ＝ #紅色
    .否則
      .如果 (編輯框_解鎖密碼框.內容 ＝ _啟動窗口.編輯框_重復密碼框.內容)
        解除屏蔽 ()
        結束 ()
      .否則
      .如果結束
    .如果結束
  .如果結束
.如果結束
.子程序 鉤子函數, 整數型
.參數 icode, 整數型
.參數 wparam, 整數型
.參數 lparam, 整數型
.局部變量 按鍵信息, 按鍵信息
CopyMemory (按鍵信息, lparam, 30)
.如果真 (icode ＝ 0)
  .如果真 (按鍵信息.虛擬碼 ＝ 91 或 按鍵信息.虛擬碼 ＝ 92) ' 屏蔽Win鍵
    .判斷開始 (wparam ＝ 256)
      輸出調試文本 (“按下Win鍵！”)
    .默認
      輸出調試文本 (“彈起Win鍵！”)
    .判斷結束
    返回 (1)
  .如果真結束
  .如果真 (按鍵信息.虛擬碼 ＝ 27 且 按鍵信息.掃描碼 ＝ 1) ' 屏蔽crlt+Esc
    返回 (1)
  .如果真結束
  .如果真 (按鍵信息.虛擬碼 ＝ 115 且 按鍵信息.掃描碼 ＝ 62) ' 屏蔽alt+f4
    返回 (1)
  .如果真結束
  .如果真 (按鍵信息.虛擬碼 ＝ 9 且 按鍵信息.掃描碼 ＝ 15) ' 屏蔽alt+TAB
    返回 (1)
  .如果真結束
  .如果真 (按鍵信息.虛擬碼 ＝ 32 且 按鍵信息.掃描碼 ＝ 57) ' 屏蔽crlt+空格 左邊
    返回 (1)
  .如果真結束
  .如果真 (按鍵信息.虛擬碼 ＝ 161 且 按鍵信息.掃描碼 ＝ 54) ' 屏蔽crlt+空格 右邊
    返回 (1)
  .如果真結束
  .如果真 (按鍵信息.虛擬碼 ＝ 160 且 按鍵信息.掃描碼 ＝ 42) ' 屏蔽crlt+SHIFT
    返回 (1)
  .如果真結束
  .如果真 (按鍵信息.虛擬碼 ＝ 46 且 按鍵信息.掃描碼 ＝ 83) ' 屏蔽CAL_DEL_ALT
    返回 (1)
  .如果真結束
.如果真結束
返回 (下一個鉤子 (鉤子句柄, icode, wparam, lparam))
.子程序 注冊屏蔽
.如果真 (鉤子句柄 ＝ 0)
  鉤子句柄 ＝ 安裝鉤子 (13, &鉤子函數, GetModuleHandleA (0), 0)
  .如果 (鉤子句柄 ≠ 0)
    輸出調試文本 (“注冊鉤子成功！”)
  .否則
    輸出調試文本 (“注冊鉤子失敗！”)
  .如果結束
.如果真結束
.子程序 解除屏蔽
.如果真 (鉤子句柄 ≠ 0)
  .如果 (卸載鉤子 (鉤子句柄) ≠ 0)
    輸出調試文本 (“缷載鉤子成功！”)
  .否則
    輸出調試文本 (“缷載鉤子失敗！”)
  .如果結束
.如果真結束
.子程序 _時鐘1_周期事件
窗口總在最前 (取窗口句柄 ())

鎖屏

.版本 2
.支持庫 eAPI
.程序集 窗口程序集2
.子程序 __啟動窗口_創建完畢
設置窗口透明度 (取窗口句柄 (), 245)
.子程序 _圖形按鈕1_被單擊
_按鈕1_被單擊 ()
.子程序 _按鈕1_被單擊
.如果 (編輯框_密碼框.內容 ≠ 編輯框_重復密碼框.內容)
  標簽_提示.標題 ＝ “密碼不一致，請重新輸入！”
  標簽_提示.文本顏色 ＝ #紅色
.否則
  .如果 (編輯框_密碼框.內容 ＝ “”)
    標簽_提示.標題 ＝ “未輸入密碼，請重新輸入！”
    標簽_提示.文本顏色 ＝ #紅色
  .否則
    _啟動窗口.可視 ＝ 假
    載入 (窗口1_鎖屏框, , 真)
  .如果結束
.如果結束
.子程序 _編輯框_密碼框_內容被改變
標簽_提示.標題 ＝ “請輸入密碼后繼續：”
標簽_提示.文本顏色 ＝ #白色
.子程序 _編輯框_重復密碼框_內容被改變
標簽_提示.標題 ＝ “請輸入密碼后繼續：”
標簽_提示.文本顏色 ＝ #白色
.子程序 _圖形按鈕_最小化_被單擊
_啟動窗口.位置 ＝ 2
.子程序 _圖形按鈕_關閉_被單擊
銷毀 ()

運行結果：

以上是“易語言如何實現電腦屏幕鎖定工具”這篇文章的所有內容，感謝各位的閱讀！相信大家都有了一定的了解，希望分享的內容對大家有所幫助，如果還想學習更多知識，歡迎關注億速云行業資訊頻道！