易語言如何查找指定顏色并將鼠標移動到指定坐標

這篇文章將為大家詳細講解有關易語言如何查找指定顏色并將鼠標移動到指定坐標，小編覺得挺實用的，因此分享給大家做個參考，希望大家閱讀完這篇文章后可以有所收獲。

DLL命令表

.版本 2
.DLL命令 移動鼠標, , "user32", "SetCursorPos"
 .參數 x, 整數型
 .參數 y, 整數型

查找指定顏色例程

.版本 2
.程序集 窗口程序集1
.子程序 _查找按鈕_被單擊, , , 查找顏色
.局部變量 臨時字節集, 字節集
.局部變量 顏色, 字節集
.局部變量 找到位置, 整數型
.局部變量 x, 整數型
.局部變量 y, 整數型
.局部變量 寬, 整數型
.局部變量 高, 整數型
臨時字節集 ＝ 快照 (, , ) ' 取屏幕
寬 ＝ 臨時字節集 [19] ＋ 臨時字節集 [20] × 256
高 ＝ 臨時字節集 [23] ＋ 臨時字節集 [24] × 256
臨時字節集 ＝ 取字節集右邊 (臨時字節集, 取字節集長度 (臨時字節集) － 54)
顏色 ＝ { 0, 0, 0 }
顏色 [1] ＝ 到字節 (到數值 (編輯框B.內容))
顏色 [2] ＝ 到字節 (到數值 (編輯框G.內容))
顏色 [3] ＝ 到字節 (到數值 (編輯框R.內容))
找到位置 ＝ -1
.循環判斷首 ()
 找到位置 ＝ 尋找字節集 (臨時字節集, 顏色, 找到位置 ＋ 1)
 .如果真 (找到位置 ＝ -1)
  跳出循環 ()
 .如果真結束
.循環判斷尾 ((找到位置 － 1) ％ 3 ≠ 0)
.如果 (找到位置 ≠ -1)
 x ＝ ((找到位置 － 1) ÷ 3 ＋ 1) ％ 寬
 y ＝ 高 － ((找到位置 － 1) ÷ 3 ＋ 1) ＼ 寬
 編輯框結果.內容 ＝ “X：” ＋ 到文本 (x) ＋ “ Y：” ＋ 到文本 (y)
 .如果真 (選擇框1.選中 ＝ 真)
  移動鼠標 (x, y)
 .如果真結束
.否則
 編輯框結果.內容 ＝ “沒有找到”
.如果結束
.子程序 _編輯框顏色值_內容被改變
.局部變量 字節集, 字節集
.局部變量 R, 整數型
.局部變量 G, 整數型
.局部變量 B, 整數型
字節集 ＝ 到字節集 (到整數 (編輯框顏色值.內容))
R ＝ 字節集 [1]
G ＝ 字節集 [2]
B ＝ 字節集 [3]
編輯框R.內容 ＝ 到文本 (R)
編輯框G.內容 ＝ 到文本 (G)
編輯框B.內容 ＝ 到文本 (B)
顏色畫板.畫板背景色 ＝ 到整數 (編輯框顏色值.內容)
.子程序 __啟動窗口_創建完畢
_編輯框顏色值_內容被改變 ()

運行結果：

關于“易語言如何查找指定顏色并將鼠標移動到指定坐標”這篇文章就分享到這里了，希望以上內容可以對大家有一定的幫助，使各位可以學到更多知識，如果覺得文章不錯，請把它分享出去讓更多的人看到。